UDF involving Split function or Formula Text?

[VBE313]

I created a UDF that calculates how many minutes it takes to complete a certain task.

(ex: =MinutesToComplete(1,0.18,10,50,20) )

Is there a way to extract each argument/parameter?

(ex: =RightParameter() ) and the answer would be 20

 

[VBE313]

I got this function from here and it gave me the all the numbers listed out in commas,
ex 1,0.18,10,50,20

How can I get these numbers separated?

https://www.mrexcel.com/forum/excel-questions/327437-custom-udf-extract-numbers.html

Function GetNumber(r As Range, Optional lIndex = 1) As String
Dim f As String, arr
f = r.formula
If Mid$(f, 1, 1) = "=" Then f = Mid$(f, 2)
f = Replace(f, "(", "~")
f = Replace(f, ")", "~")
arr = Split(f, "~")
On Error Resume Next
GetNumber = arr(lIndex * 2 - 1)
End Function

 

[VBE313]

SOLVED!
https://www.exceltip.com/tips/how-t...string-using-vba-in-microsoft-excel-2010.html

Function ExtractNthWord(x As String, y As Integer)
Dim word() As String
Dim wordCount As Long
word() = VBA.Split(x, ",")
wordCount = UBound(word)
If wordCount < 1 Or (y - 1) > wordCount Or y < 0 Then
ExtractNthWord = ""
Else
ExtractNthWord = word(y - 1)
End If
End Function

 

[mikerickson]

This UDF might help.
If a cell contains a formula that is only one function, like =MyUDF(arg1, arg2, arg3) this will return the indicated argument in that formula.
Note that commas inside quote marks e.g. =LEN("abc,xyz,def") are not counted as argument seperators

Function FunctionArguments(formulaCell As Range, ArgumentIndex As Long) As String
    Dim strFormula As String
    Dim Pointer As Long, i As Long, flag As Boolean
    strFormula = formulaCell.Cells(1, 1).Formula
    If strFormula Like "*)" Then strFormula = Left(strFormula, Len(strFormula) - 1) & ","
    For Pointer = 1 To Len(strFormula)
        If Mid(strFormula, Pointer, 1) = "(" Then Exit For
    Next Pointer
    
    If Len(strFormula) < Pointer Then
        Rem no function e.g. =5
        FunctionArguments = "-"
    Else
        Do
            Pointer = Pointer + 1
            If (Not flag) And (Mid(strFormula, Pointer, 1) = ",") Then
                Rem found one argument
                ArgumentIndex = ArgumentIndex - 1
                If ArgumentIndex = 0 Then
                    Exit Function
                Else
                    FunctionArguments = vbNullString
                End If
            Else
                FunctionArguments = FunctionArguments & Mid(strFormula, Pointer, 1)
                If Mid(strFormula, Pointer, 1) = Chr(34) Then flag = Not flag
            End If
        Loop Until Len(strFormula) < Pointer
    End If
End Function

 

[VBE313]

mikerickson,

Thank you very much! It is doing what I wanted and was even easier than what I had.

THANK YOU!