Two ways to reference, which is smart design?

[jmpatrick]

Hello!

I have two simple sample pieces of code. They both do the same thing and they both work. My question is: which is correct? The second example is less text. Does that make it run any faster? Is there a downside?

Sub TestOpen()

        SearchEdit.Show
        SearchEdit.SE_MS_select.Visible = False
        SearchEdit.MS_warning.Visible = False
        SearchEdit.SE_ModelIndication.Visible = False
        SearchEdit.SE_DatePending.Visible = False
        SearchEdit.SE_DateConfirmed.Visible = False
        SearchEdit.SE_DateUnConfirmed.Visible = False
        SearchEdit.SE_Confirm.Visible = False
        SearchEdit.SE_Unconfirm.Visible = False
        SearchEdit.cmdNotPending.Visible = False

       SearchEdit.SE_Notes_11.Value = Sheets("Calendar").Range("FA" & ActiveCell.Row).Value

End Sub

Sub TestOpen2()

With SearchEdit
   
        .Show
        .SE_MS_select.Visible = False
        .MS_warning.Visible = False
        .SE_ModelIndication.Visible = False
        .SE_DatePending.Visible = False
        .SE_DateConfirmed.Visible = False
        .SE_DateUnConfirmed.Visible = False
        .SE_Confirm.Visible = False
        .SE_Unconfirm.Visible = False
        .cmdNotPending.Visible = False
       
End With

End Sub

Also related, I've noticed that this code works:

SearchEdit.SE_Notes_11.Value = Sheets("Calendar").Range("FA" & ActiveCell.Row).Value

...and so does this:

SE_Notes_11 = Sheets("Calendar").Range("FA" & ActiveCell.Row)

The second example is "cleaner," but is it any more efficient (speed-wise)?

 

[MARK858]

Does that make it run any faster?

The 2nd code only evaluates SearchEdit once so it is more efficient but you'd only notice it on large data (it also is less typing)

The second example is "cleaner," but is it any more efficient (speed-wise)?

My answer is not that I am aware of

My question is: which is correct?

They both are as they both work correctly and give the correct result

 

[jmpatrick]

Thanks!

 

[MARK858]

You're welcome

 

[Edgar_]

Also related, I've noticed that this code works:
SearchEdit.SE_Notes_11.Value = Sheets("Calendar").Range("FA" & ActiveCell.Row).Value
...and so does this:
SE_Notes_11 = Sheets("Calendar").Range("FA" & ActiveCell.Row)
The second example is "cleaner," but is it any more efficient (speed-wise)?

Those two snippets work and some others as verbose as the following two should also work:

SearchEdit.Controls.Item("SE_Notes_11").Value = Application.ThisWorkbook.Sheets.Item("Calendar").Range("FA" & Application.ActiveCell.Row).Value
SearchEdit.Controls!SE_Notes_11 = Sheets!Calendar.Range("FA" & Application.ActiveCell.Row).Value

VBA offers flexibility with both implicit and explicit references. While the performance impact of implicit references is typically negligible, it can become significant when dealing with thousands of iterations. To avoid ambiguity and unnecessary resource usage, it’s generally better to write explicit code. For instance, SearchEdit.SE_Notes_11 could refer to either the control or its value, depending on the context; since you're trying to get a value in your example, VBA uses its resources to determine that you actually meant SearchEdit.SE_Notes_11.Value. But if you had something like this, it would return an object:

Dim myControl As Object
Set myControl = SearchEdit.SE_Notes_11

Therefore, you could do this:
Msgbox myControl.Width

How can you know what it will return? take a look at the object browser, when a member of an object is the default one, it has a cyan icon next to it and the description tells you it is the default member. Intellisense also hints that.

 

[RoryA]

Also related, I've noticed that this code works:

SearchEdit.SE_Notes_11.Value = Sheets("Calendar").Range("FA" & ActiveCell.Row).Value

...and so does this:

SE_Notes_11 = Sheets("Calendar").Range("FA" & ActiveCell.Row)

The second example is "cleaner," but is it any more efficient (speed-wise)?

The second one will only work if the code is in that form. If it is, you should really be using that second version, not the prior one, since the userform is effectively a class and the second one is really short for Me.SE_Notes_11 = ... which will always refer to the current instance of the class.