Transfer of data range (multiple cells) from one sheet to another sheet automatically at the next blank row.

[SomethingNew]

First time posting sorry if I am not posting properly.

I have used the code below previously to automatically input data from one cell to a master data sheet but now I need it to input multiple cells down the column.

Sub data_input()

ws_output = "SAMPLE FINAL"

next_row = Sheets(ws_output).Range("B" & Rows.Count).End(xlUp).Offset(1).Row

Sheets(ws_output).Cells(next_row, 1).Value = Range("DESCRIPTION").Value
Sheets(ws_output).Cells(next_row, 18).Value = Range("QTY").Value
Sheets(ws_output).Cells(next_row, 19).Value = Range("UOM").Value

End Sub

To make it submit multiple cells information I tried changing the column range's name instead of just the one singular cell.
ex.
Range A2:A12 changed name to DESCRIPTION

It only accepts the first row of the range and nothing else is listed below, I am unsure if my approach is completely wrong since I assumed the range of cells is included in the Range("DESCRIPTION").Value.

If there's another way to do this or if I'm just making a mistake in my approach I would appreciate any help

 

[Alex Blakenburg]

When you use an assignment ie .value = .value the range sizes on both sides of the "=" need to be the same size.
Assuming your 3 range names are all the same size, try something like this:

Sub data_input()

Dim ws_output As String
Dim next_row As Long
Dim NoOfRows As Long

ws_output = "SAMPLE FINAL"

next_row = Sheets(ws_output).Range("B" & Rows.Count).End(xlUp).Offset(1).Row

NoOfRows = Range("Description").Count

With Sheets(ws_output)
    .Cells(next_row, 1).Resize(NoOfRows).Value = Range("DESCRIPTION").Value
    .Cells(next_row, 18).Resize(NoOfRows).Value = Range("QTY").Value
    .Cells(next_row, 19).Resize(NoOfRows).Value = Range("UOM").Value
End With

End Sub

 

[SomethingNew]

Thank you so much for this, it's made the column off by 1 but I just changed the

.Cells(next_row, 1).Resize(NoOfRows).Value = Range("DESCRIPTION").Value

into

.Cells(next_row, 2).Resize(NoOfRows).Value = Range("DESCRIPTION").Value

just for reference in case anyone tries it.

Thank you again.

 

[Alex Blakenburg]

You're welcome. Glad you got it working.