Tiered Commissions Calc

[lcblick]

Hi,
I was wondering if someone could help me with this.
I have a tiered commissions structure as follows:
0-100% attainment (Total payout of 100% of eligible %)
100-125% (total payout of 1.5% of eligible %)
125%+ (total payout of 2.5% of eligible %)
accelerated commission rate not to exceed 15%

In addition, a secondary quota will be assigned . If this quota is hit, a 10% bonus calced on the full amount of commissioned revenue will deternmine amount.

Thank You...

 

[Dave Patton]

Please check your description and provide a couple of examples with expected results.

 

[lcblick]

Thanks Dave.
Let's say that on achievement (Revenue vs. Goal) of anywhere between 0 and 100%, payout is 5% of the revenue. If $100k revenue and $100k goal, assume $5,000 payout
If the achievement is 110% ($110,000 vs $100k goal), payout would be $5,000 on the 1st $100k and then 1.5 X the 1st 5% or 7.5% of $10k or an additional $750\
If achievement is 130% ($130k vs $100k goal), payout would be $5k + 7.5%x$25k ($1875) +12.5%x$5k ($625)

I hope that helps. It's basically calculating commissions after meeting the tresholds of multiple tiers. Once you exceed a tier, you are paid in full on that tier and the balnce is paid on the next tier, etc.

Thanks...

0-100% attainment (Total payout of 100% of eligible %)
100-125% (total payout of 1.5% of eligible %)
125%+ (total payout of 2.5% of eligible %)
accelerated commission rate not to exceed 15%

In addition, a secondary quota will be assigned . If this quota is hit, a 10% bonus calced on the full amount of commissioned revenue will deternmine amount

 

[Dave Patton]

Excel 2010
	A	B	C	D	E	F	G
1	Amount	Goal	Attainment	Commission	Bracket	Rate	Rate Diff
2	100,000.00	100,000.00	100%	$5,000.00	0	5.0%	5.0%
3					100,000	7.5%	2.5%
4					125,000	12.5%	5.0%
6b

Cell Formulas
Range	Formula
C2	=A2/B2
D2	=SUMPRODUCT(--(A2>E2:E4),A2-E2:E4,G2:G4)
E3	=B2
E4	=B2*1.25
G2	=F2-N(F1)
G3	=F3-N(F2)
G4	=F4-N(F3)

 

[lcblick]

Please check your description and provide a couple of examples with expected results.

Thanks so much. That appears to do the trick.

 

[lcblick]

Thanks for this. Is there a way that I can show the Commission breakout by tier? Much appreciated.

 

[Dave Patton]

Excel 2010
	A	B	C	D	E	F	G	H
1	Amount	Goal	Attainment	Commission	Bracket	Rate	Rate Diff
2	130,000.00	100,000.00	130%	$7,500.00	0	5.0%	5.0%	5,000.00
3					100,000	7.5%	2.5%	1,875.00
4					125,000	12.5%	5.0%	625.00
5
6b

Cell Formulas
Range	Formula
C2	=A2/B2
D2	=SUMPRODUCT(--(A2>E2:E4),A2-E2:E4,G2:G4)
E3	=B2
E4	=B2*1.25
F3	=1.5*F2
F4	=2.5*F2
H2	=MIN($A$2,E3-E2)*F2
H3	=MIN($A$2-100000,E4-E3)*F3
H4	=(A2-E4)*F4

 

[lcblick]

Excel 2010

	A	B	C	D	E	F	G	H
Amount	Goal	Attainment	Commission	Bracket	Rate	Rate Diff

<colgroup><col style="width: 25pxpx"><col><col><col><col><col><col><col><col></colgroup><thead>
</thead><tbody>
[TD="align: center"]1[/TD]

[TD="align: right"][/TD]

[TD="align: center"]2[/TD]
[TD="align: right"]130,000.00[/TD]
[TD="align: right"]100,000.00[/TD]
[TD="align: right"]130%[/TD]
[TD="bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=92D050]#92D050[/URL] , align: right"]$7,500.00[/TD]
[TD="align: right"]0[/TD]
[TD="align: right"]5.0%[/TD]
[TD="align: right"]5.0%[/TD]
[TD="bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=92D050]#92D050[/URL] , align: right"]5,000.00[/TD]

[TD="align: center"]3[/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"]100,000[/TD]
[TD="align: right"]7.5%[/TD]
[TD="align: right"]2.5%[/TD]
[TD="bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=92D050]#92D050[/URL] , align: right"]1,875.00[/TD]

[TD="align: center"]4[/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"]125,000[/TD]
[TD="align: right"]12.5%[/TD]
[TD="align: right"]5.0%[/TD]
[TD="bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=92D050]#92D050[/URL] , align: right"]625.00[/TD]

[TD="align: center"]5[/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]
[TD="align: right"][/TD]

</tbody>

6b​

[TABLE="width: 85%"]
<tbody>[TR]
[TD]Worksheet Formulas[TABLE="width: 100%"]
<thead>[TR="bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]
[TH="width: 10px"]Cell[/TH]
[TH="align: left"]Formula[/TH]
[/TR]
</thead><tbody>[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]C2[/TH]
[TD="align: left"]=A2/B2[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]D2[/TH]
[TD="align: left"]=SUMPRODUCT(--(A2>E2:E4),A2-E2:E4,G2:G4)[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]E3[/TH]
[TD="align: left"]=B2[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]F3[/TH]
[TD="align: left"]=1.5*F2[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]E4[/TH]
[TD="align: left"]=B2*1.25[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]F4[/TH]
[TD="align: left"]=2.5*F2[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]H2[/TH]
[TD="align: left"]=MIN($A$2,E3-E2)*F2[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]H3[/TH]
[TD="align: left"]=MIN($A$2-100000,E4-E3)*F3[/TD]
[/TR]
[TR]
[TH="width: 10px, bgcolor: [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=DAE7F5]#DAE7F5[/URL] "]H4[/TH]
[TD="align: left"]=(A2-E4)*F4[/TD]
[/TR]
</tbody>[/TABLE]
[/TD]
[/TR]
</tbody>[/TABLE]

Thanks again. What happens if the attainment is 100 or less? I am getting the 2nd and 3rd tiers showing negative numbers.

 

[lcblick]

Thank you so much. The issue I am facing is if the 2nd and 3rd tiers are showing negative numbers if the attainment is 100 or less. Those tiers should show zero and only the 1st tier should shoe me the value.

 

[Dave Patton]

I thought your would revise the formulas for your actual requirements.
You can review the following and hopefully some part will address your issues.

Excel 2010
	A	B	C	D	E	F	G	H
1	Amount	Goal	Attainment	Commission	Bracket	Rate	Rate Diff	Attainment tiered commission
2	130,000.00	100,000.00	130%	$7,500.00	0	5.0%	5.0%	5,000.00
3					100,000	7.5%	2.5%	1,875.00
4					125,000	12.5%	5.0%	625.00
5					130,000
6
7
8				Tier # 1	Tier # 2	Tier # 3
9			Rate	5.0%	7.5%	12.5%
10	Goal	100,000.00	Tier from	0	100,000.00	125,000.00
11	Actual	130,000.00	Tier to	100,000.00	125,000.00	130,000.00
12	Commission			$5,000.00	$1,875.00	$625.00
13
14				$5,000.00	$1,875.00	$625.00
15				$5,000.00	$1,875.00	$625.00
6b

Cell Formulas
Range	Formula
C2	=A2/B2
D2	=SUMPRODUCT(--(A2>E2:E4),A2-E2:E4,G2:G4)
D11	=B10
D12	=MAX(0,MIN($B$11-D10,D11-D10))*D9
D14	=($B$11>D10)*MIN($B$11,D11-D10)*D9
D15	=($B$11>0)*MIN($B$11,100000-0)*0.05
G2	=F2-N(F1)
G3	=F3-N(F2)
G4	=F4-N(F3)
H2	=MAX(0,MIN($A$2-E2,E3-E2))*F2
H3	=MAX(0,MIN($A$2-E3,E4-E3))*F3
H4	=MAX(0,MIN($A$2-E4,E5-E4))*F4
E3	=B2
E4	=B2*1.25
E5	=A2
E10	=D11
E11	=B10*1.25
E12	=MAX(0,MIN($B$11-E10,E11-E10))*E9
E14	=($B$11>E10)*MIN($B$11,E11-E10)*E9
E15	=($B$11>100000)*MIN($B$11,125000-100000)*0.075
F3	=1.5*F2
F4	=2.5*F2
F10	=E11
F11	=B11
F12	=MAX(0,MIN($B$11-F10,F11-F10))*F9
F14	=($B$11>F10)*MIN($B$11,F11-F10)*F9
F15	=($B$11>125000)*MIN($B$11,B11-125000)*0.125