TEXTJOINARRAY

[RicoS]

TEXTJOINARRAY Joins the text in an array by row or column, with delimiter

=LAMBDA(array,delimiter,byColumn,
   LET(
      a,IF(byColumn,TRANSPOSE(array),array),
      d,delimiter,
      s,SEQUENCE(ROWS(a),1,0),
      tj,TEXTJOIN(d,TRUE,a),
      l,LEN(d),seqL,(s*0)+(l*COLUMNS(a)),
      end,SUMCUMULATIVE(SUMROWS(LEN(a)+l)),
      start,IF(s=0,1,1+INDEX(seqL,s,1)+INDEX(end,s,1)),
      md,MID(tj,start,end-start+1),
      return,IF(byColumn,TRANSPOSE(md),md),
   return)
)

Lambda - Last Cell and Split.xlsx
	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Original Array
2	test this	t	e	s	t		t	h	i	s
3	this test	t	h	i	s		t	e	s	t
4	further test	f	u	r	t	h	e	r		t	e	s	t
5
6
7	Text join
8	test this
9	this test
10	further test
Sheet1

Cell Formulas
Range	Formula
C2:N4	C2	=TEXTTOARRAY(B2:B4)
B8:B10	B8	=TEXTJOINARRAY(C2#,"",)
Dynamic array formulas.

 

[smozgur]

Note: Refer to the TEXTTOARRAY function used in the sample above.

@RicoS - you can include links to the extra Lambda functions used in a sample to make it easier to find them. Thanks!

 

[RicoS]

Apologies, I'll go through them all just now and add the links. I knew I missed something!

The following LAMBDA functions are utilised in TEXTJOINARRAY:
SUMCUMULATIVE
SUMROWS

With the example showing:
TEXTTOARRAY

 

[smozgur]

Apologies, I'll go through them all just now and add the links. I knew I missed something!

No worries!

Great Lambda implementations! Thanks for sharing with us.