Text to Columns as Formula

[slam]

I have a column with cells that look like this:

95.68#88
63.71#999
99.84#144

Is it possible to replicate text to columns, but as a formula? Using the # as the delimiter, then having the two values split into two columns?

Essentially, I just want to paste the data, then have a formula automatically split the numbers into two columns.

Thanks!

 

[Fluff]

How about

Fluff.xlsm
	A	B	C
1
2	95.68#88	95.68	88
3	63.71#999	63.71	999
4	99.84#144	99.84	144
Sheet6

Cell Formulas
Range	Formula
B2:C4	B2	=--TEXTSPLIT(A2,"#")
Dynamic array formulas.

 

[johnny51981]

There are 2.
Before Delimiter

=NUMBERVALUE(TEXTBEFORE($A2,"#"))

After Delimiter

=NUMBERVALUE(TEXTAFTER($A2,"#"))

 

[Sergius]

Book1
	A	B	C	D
1	95.68#88		95.68	88
2	63.71#999		63.71	999
3	99.84#144		99.84	144
4	63.71#999		63.71	999
5	99.84#144		99.84	144
Sheet1

Cell Formulas
Range	Formula
C1:C5	C1	=MID(A1,1,SEARCH("#",A1)-1)
D1:D5	D1	=MID(A1,SEARCH("#",A1)+1,100)

 

[slam]

Just amazing how many different ways there are to do things in Excel!

I had some cells that only contained a dash in this range, and I needed to add an error condition in for that, which I got working with the solution from Sergius, so my two formulas are:

=IFERROR(MID(I2,1,SEARCH("#",I2)-1),"-")

=IFERROR(MID(I2,SEARCH("#",I2)+1,100),"-")

Big thank you to you all!

 

[Fluff]

Glad we could help & thanks for the feedback.