text file editing in bulk (batch file)

[mcranmoss]

I'm wanting to edit identical text in a large number of text files using a batch file. This sample code is attempting to test the principle. But all it does is open the text file.

any advice welcome.

mark

@echo off
setlocal enabledelayedexpansion
if not exist "%1" V:\Mark\VBA_Excel\BATCHTEST\New.txt &goto :eof
set /p findthis=BOB:
set /p replacewith=FLUTE:

for /f "tokens=*" %%a in (%1) do (
   set write=%%a
   if %%a==%findthis% set write=%replacewith%
   echo !write! 
   echo !write! >>%~n1.replaced%~x1
)

 

[hrlngrv]

Basic advice: ask real experts. In this case that means using the alt.msdos.batch.nt newsgroup which is available via Google Groups if you ISP doesn't provide nntp newsgroup access.

You seem to be replacing entire lines. If so, I'd use a subroutine call.

@echo off & setlocal enableextensions

if not exist "%~1" (
        echo/%~0: file "%~1" doesn't exist
        goto :EOF
) else (
        set out="%~dpn1.replaced%~x1"
)

set/P f=find:
if "%f%" == "" (
        echo/%~0: no find string, nothing to do, ending
        goto :EOF
)

set/P r=replace:
if "%r%" == "" (
        echo/%~0: no replace string, deleting find string '%f%'
)

for /F "delims=" %%a in (%1) do call :PROC "%%a"

goto :EOF

:PROC
(if "%~1" == "%f%" (
        if not "%r%" == "" echo/%r%
) else (
        echo/%1
)) >> %out%

Note that the %1 parameter in :PROC is the %%a from the for loop.

ALWAYS enclose arbitrary filename parameters in quotes AFTER removing possible quotes in the filename parameter. That is, NEVER user either %1 or "%1", ALWAYS use "%~1". Do the same for for loop parameters used in if tests, e.g., "%%~a". Also enclose environment variables in quotes when you use them in if tests.

The for loop options "tokens=*" and "delims=" should produce the same results, but in my expereince the latter is more robust.

Finally, enabledelayedexpansion can be very screwy. Much better not to use it but instead call subroutines with the current loop's parameters %%a, %%b, etc.