T_CHARS

[Xlambda]

T_CHARS tool lambda to select chars useful in recursive text manipulation formulas

=LAMBDA(d,l,e,
    LET(c,AND(OR(d={0,1}),OR(l={-1,0,1,2})),
       u,CONCAT(SEQUENCE(10)-1),v,CONCAT(CHAR(SEQUENCE(26,,97))),w,UPPER(v),
       x,IF(d,u,""),y,SWITCH(l,-1,v,0,"",1,w,2,v&w,""),z,IF(e=0,"",e),
       IF(c,x&y&z,"check data")
    )
)

LAMBDA 7.0.xlsx
	A	B	C	D	E	F	G	H	I
1	d-digits	0	1
2		no digits	all digits
3	l-letters	0	-1	1	2
4		no letters	small letters	capital letters	all letters
5	e-extra chars
6
7	=T_CHARS(1,,)
8	0123456789
9	=T_CHARS(,-1,123)
10	abcdefghijklmnopqrstuvwxyz123
11	=T_CHARS(1,1,"bcdf")
12	0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZbcdf
13	=T_CHARS(1,,""""&"!·$%&/()=?")
14	0123456789"!·$%&/()=?
15	=T_CHARS(,-1,"ZIP-")
16	abcdefghijklmnopqrstuvwxyzZIP-
17	=T_CHARS(,2,""""&"!·$%&/()=?¿<>\@€:;,.-_")
18	abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"!·$%&/()=?¿<>\@€:;,.-_
19	=T_CHARS(1,2,)
20	0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
21
T_CHARS post

Cell Formulas
Range	Formula
A7,A19,A17,A15,A13,A11,A9	A7	=FORMULATEXT(A8)
A8	A8	=T_CHARS(1,,)
A10	A10	=T_CHARS(,-1,123)
A12	A12	=T_CHARS(1,1,"bcdf")
A14	A14	=T_CHARS(1,,""""&"!·$%&/()=?")
A16	A16	=T_CHARS(,-1,"ZIP-")
A18	A18	=T_CHARS(,2,""""&"!·$%&/()=?¿<>\@€:;,.-_")
A20	A20	=T_CHARS(1,2,)

 

[Xlambda]

Same functionality, same arguments, tweaks added, omitted able arguments, extra chars "e" can be in any array shape now. Other functions on minisheet: AFILL
Very useful tool in text manipulation functions, for removing, replacing, keeping certain chars.

=LAMBDA([d],[l],[e],
    LET(x,1234567890,y,"abcdefghijklmnopqrstuvwxyz",z,UPPER(y),w,TEXTJOIN("",,e),
      a,SWITCH(d,0,"",1,x),b,SWITCH(l,0,"",-1,y,1,z,2,y&z),
      IFNA(a&b&w,"check arg.")
    )
)

LAMBDA 1.1.2.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R
4	1	all digits
5	l:	letters
6	0	or omitted, no letters					wrong arguments					using quotes
7	-1	all small letters					d,3			d,1,l,4		e,|"		e,|""
8	1	all capital letters					=T_CHARS(3)			=T_CHARS(1,4)		=T_CHARS(,,"|""")		=T_CHARS(,,"|""""")
9	2	small and capital letters					check arg.			check arg.		|"		|""
10	e:	extra characters
11		string or array of strings,or AFILL construction
12
13		all omitted		d,1		d,omitt.,l,-1				d,1,l,-1				e,digits 0 to 3		e,digits 0 to 3
14		=T_CHARS()		=T_CHARS(1)		=T_CHARS(,-1)				=T_CHARS(1,-1)				=T_CHARS(,,1230)		=T_CHARS(,,"0123")
15				1234567890		abcdefghijklmnopqrstuvwxyz				1234567890abcdefghijklmnopqrstuvwxyz				1230		0123
16
17						d,omitt.,l,1				d,1,l,2
18						=T_CHARS(,1)				=T_CHARS(1,2)
19						ABCDEFGHIJKLMNOPQRSTUVWXYZ				1234567890abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
20
21						d,omitt.,l,2
22						=T_CHARS(,2)
23						abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
24				e,string
25				=T_CHARS(,,"\|@#~")
26				\|@#~
27	e,array
28	✌	⏰		d,1,e,array				d,1,e,AFILL construction			AFILL
29	%			=T_CHARS(1,,A28:B30)				=T_CHARS(1,,AFILL({"","%&/"},UNICHAR(9996)&UNICHAR(9200)))
30	&	/		1234567890✌⏰%&/				1234567890✌⏰%&/
31								Using versatility of AFILL, hybrid array of constant array and formulas/functions
32								We can hardcode known unicode chars togheter with a constant string
33
new T_CHARS

Cell Formulas
Range	Formula
G8,D29,H29,D25,F22,J18,F18,D14,N14,P14,J14,F14,B14,J8,L8,N8	G8	=FORMULATEXT(G9)
G9	G9	=T_CHARS(3)
J9	J9	=T_CHARS(1,4)
L9	L9	=T_CHARS(,,"|""")
N9	N9	=T_CHARS(,,"|""""")
B15	B15	=T_CHARS()
D15	D15	=T_CHARS(1)
F15	F15	=T_CHARS(,-1)
J15	J15	=T_CHARS(1,-1)
N15	N15	=T_CHARS(,,1230)
P15	P15	=T_CHARS(,,"0123")
F19	F19	=T_CHARS(,1)
J19	J19	=T_CHARS(1,2)
F23	F23	=T_CHARS(,2)
D26	D26	=T_CHARS(,,"\|@#~")
D30	D30	=T_CHARS(1,,A28:B30)
H30	H30	=T_CHARS(1,,AFILL({"","%&/"},UNICHAR(9996)&UNICHAR(9200)))