Swe: Letarad (?) med VBa kod

[Boy from the north countr]

Aloha,

Jag håller på med ett litet VBAprojekt. Userform som bara har två inmatningar, har jag fått att fungera fint.

Mitt blad består av ca 600 rader med ort, leverantör, tonpriser och drivmedelstilägg. Vad jag vill göra är att när jag väljer leverantör från en combobox och fyller i drivmedelstillägget i en textbox så vill jag att programmet går igenom C kolumnen där alla leverantörer finns och sedan uppdaterar L kolumnen med det värde på drivmedelstilägget (DMT) som jag anget i textboxen.
Nu till min fråga.
Hur kan jag skriva koden så att drivmedelstillägget uppdateras på alla rader där leverantören stämer överens med den angivna leverantören i comboboxen.
Än så länge har jag bara kommit fram till att
ActiveCell.Offset(0, 9) = txtdmt.Value fungerar bra för att lägga in DMT i L kolumnen, men hur jag får programmet att göra detta på de rader där mitt combobox val stämmer överens med det värde som står i C kolumnen vet jag ej.

Går det överhuvudtaget att förstå min fråga vore jag tacksam för svar.

 

[fairwinds]

Hej,

Förutom combobox och textbox på din userform så satte jag dit en
kommando knapp att trycka på när du fyllt i klart.

Koden för knappen kan vara ungefär:

Private Sub CommandButton1_Click()
Dim ce As Range

For Each ce In Sheet1.Range("C2", Range("C65536").End(xlUp))

If ce = ComboBox1.Value Then ce.Offset(0, 9) = TextBox1.Value

Next ce

End Sub

Hoppas du kan göra de ev anpassningar som behövs.

 

[XL-Dennis]

Hej på Er

Jag hade vägarna förbi så jag skrev ihop en lite annorlunda lösning i sin helhet:

Option Explicit
Dim wbBook As Workbook
Dim wsSheet As Worksheet
Dim rnData As Range

Private Sub CommandButton1_Click()
Dim rnFind As Range
Dim stValue As String, stFind As String
Dim stAddress As String

With Me
    stValue = .TextBox1.Text
    stFind = .ComboBox1.Value
End With

With rnData
    Set rnFind = .Find(What:=stFind)
    If Not rnFind Is Nothing Then
        stAddress = rnFind.Address
        Do
            rnFind.Offset(0, 9).Value = stValue
            Set rnFind = .FindNext(rnFind)
        Loop While Not rnFind Is Nothing And rnFind.Address <> stAddress
    End If
End With

End Sub

Private Sub UserForm_Initialize()
Dim vaData As Variant
Set wbBook = ThisWorkbook

With wbBook
    Set wsSheet = .Worksheets("Blad1")
End With

With wsSheet
    Set rnData = .Range("C1:C10")
End With

vaData = rnData.Value

With Me.ComboBox1
    .Clear
    .List = vaData
    .ListIndex = -1
End With

End Sub

 

[Boy from the north countr]

Aloha,

Tusentvå tack för hjälpen, nu borde jag få det att funka!

 

[XL-Dennis]

Yes