SUMIFS formula column based on Cell reference

[conorrey]

HI,
I have a SUMIFS formula like below. How can I get the Sum Column to change based on a cell value.

So currently it is set to sum column F. if I changed a drop down list named REVTYPE to a heading in column G how can i get the SUNIFS formula to sum that column instead of F.

Any help would be great.

Conor

This is the formula
=SUMIFS('2023 by Created Date'!F:F,'2023 by Created Date'!$M:$M,$V14,'2023 by Created Date'!$P:$P,">="&'This Week Created Bookings'!$W$9,'2023 by Created Date'!$P:$P,"<="&'This Week Created Bookings'!$W$10,'2023 by Created Date'!A:A,">="&$AA$9,'2023 by Created Date'!A:A,"<="&$AA$10,'2023 by Created Date'!O:O,$W$12)

This is where the Data is

Arrival

Departure

Alias

Res #

Pax

RHIRE

FOOD

BEV

OTHER

SUB-TOTAL

ACCOM

TOTAL

Segment

Method

Status

Created

45262​

45262​

Test

123456​

1​

0​

282.82​

24.39​

41.46​

348.67​

0​

348.67​

LIKE

TEL

Confirmed

45208​

Named Range REVTYPE

RHIRE

FOOD

BEV

OTHER

SUB-TOTAL

ACCOM

TOTAL

 

[Fluff]

Which cell has the name of the column you want to sum?

 

[conorrey]

Which cell has the name of the column you want to sum?

The name is in cell V11.

Thanks
Conor

 

[Fluff]

Ok, how about

=SUMIFS(INDEX('2023 by Created Date'!F:Z,0,XMATCH($V$11,'2023 by Created Date'!$F$1:$Z$1)),'2023 by Created Date'!$M:$M,$V14,'2023 by Created Date'!$P:$P,">="&'This Week Created Bookings'!$W$9,'2023 by Created Date'!$P:$P,"<="&'This Week Created Bookings'!$W$10,'2023 by Created Date'!A:A,">="&$AA$9,'2023 by Created Date'!A:A,"<="&$AA$10,'2023 by Created Date'!O:O,$W$12)

 

[conorrey]

Thank you. that worked great

 

[Fluff]

You're welcome & thanks for the feedback.