Sum together the larger amount of two ranges by row

[missingsc]

I have to believe this has been solved before, but I could not find a previous post for my particular problem, so apologies if I missed a previous one. I'm trying to use SUMIF/SUMIFS or some variation of formula to look at two different columns of price amounts, determine for each row which of the price amounts is larger, and then sum the larger of those amounts together. Basically wanting the largest possible sum between the two columns of data. Here's some mock data for an example:

A	B
100	200
300	100
400	800
500	250
200	400

So, for example, I would sum these ranges and it would say:

• Row 1: 200 is larger than 100
• Row 2: 300 is larger than 100
• Row 3: 800 is larger than 400
• Row 4: 500 is larger than 250
• Row 5: 400 is larger than 200
• Final amount is 2200.

I tried some variations of SUMIF and SUMIFS but could not get it to work. Any help you can provide would be greatly appreciated!

 

[Cubist]

Few options:

Book1
	A	B	C	D	E
1
2	100	200		2200	2200
3	300	100
4	400	800
5	500	250
6	200	400
Sheet1

Cell Formulas
Range	Formula
D2	D2	=SUM(BYROW(A2:B6,MAX))
E2	E2	=SUM(IF(B2:B6>A2:A6,B2:B6,A2:A6))

 

[missingsc]

Thank you! The first option works great, but I forgot to specify that the columns are not contiguous. How would you use the BYROW option if the amounts to compare are in columns A and C instead?

 

[Cubist]

You can stack them together with HSTACK.

=SUM(BYROW(HSTACK(A2:A6,C2:C6),MAX))