sum or subtract based on optuinbutton number on userform to column inside sheet

[Maklil]

Hello
I want adding or subtract when the values writing in textbox2 to column D based on matching ID in textbox1 with column C inside the sheet

original data in the sheet

ASDD.xlsm
	A	B	C	D
1	ITEM	DATE	ID	QTY
2	1	25/06/2023	SDFR-1000	20.00
3	2	26/06/2023	SDFR-1001	20.00
4	3	26/05/2023	SDFR-1002	200.00
5	4	27/05/2023	SDFR-1003	201.00
SH

if select optionbutton 1IMPORT then will sum to column C after matching ID as marked the cell

and when select option button 2 (EXPORTR) then will subtract from column C for the ID (picture 2 depends on picture1 )

and if select optionbutton3(RE) then will sum to column C for the ID (picture 3 depends on pictur2 )

and if select optionbutton 4(ER) then will subtract from column C for the ID (picture 4 depends on picture31 )

 

[DanteAmor]

Try this:

Private Sub CommandButton1_Click()
  Dim f As Range
  
  'Validations
  With TextBox1
    If .Value = "" Then
      MsgBox "Enter ID"
      .SetFocus
      Exit Sub
    End If
    Set f = Range("C:C").Find(.Value, , xlValues, xlWhole, , , False)
    If f Is Nothing Then
      MsgBox "ID does not exists"
      .SetFocus
      Exit Sub
    End If
  End With
  With TextBox2
    If .Value = "" Or Not IsNumeric(.Value) Then
      MsgBox "Enter QTY"
      .SetFocus
      Exit Sub
    End If
  End With
  
  'Sum or subtract
  With f.Offset(, 1)
    Select Case True
      Case OptionButton1 Or OptionButton3
        .Value = .Value + Val(TextBox2.Value)
      Case OptionButton2 Or OptionButton4
        .Value = .Value - Val(TextBox2.Value)
      Case Else
        MsgBox "No option was selected"
    End Select
  End With
End Sub

It is recommended, instead of textbox1, you should put a combobox to select the ID instead of capturing the entire ID.

 

[Maklil]

It is recommended, instead of textbox1, you should put a combobox to select the ID instead of capturing the entire ID.

without any doubt , that's correct I will change it .
thank you for your assistance.