sum filter based on date

[288enzo]

Hi all,

I'm working on a calendar view budget forecast and found a few helpful videos. One formula I found very helpful is:

Not an excel formula, wasn't sure what to use to properly format. This is in Google Sheets.

=IFERROR(SUM(FILTER(Recurring!$C$2:$C,
    (B5 >= Recurring!$E$2:$E) *
    (
        (Recurring!$G$2:$G = "Once") * (B5 = Recurring!$E$2:$E) +
        (Recurring!$G$2:$G = "Weekly") * (MOD(DAYS(B5, Recurring!$E$2:$E),7)=0)+
        (Recurring!$G$2:$G = "Monthly") * (DAY(B5)=DAY(Recurring!$E$2:$E))
    )
)),"")

What I need some assistance on is how to add another condition to the filter.

As an example, what I thought would work is:

=IFERROR(SUM(FILTER(Recurring!$C$2:$C,
    (B5 >= Recurring!$E$2:$E, B5 < Recurring!$F$2:$F) *
    (
        (Recurring!$G$2:$G = "Once") * (B5 = Recurring!$E$2:$E) +
        (Recurring!$G$2:$G = "Weekly") * (MOD(DAYS(B5, Recurring!$E$2:$E),7)=0)+
        (Recurring!$G$2:$G = "Monthly") * (DAY(B5)=DAY(Recurring!$E$2:$E))
    )
)),"")

Recurring!$E$2:$E = start date
Recurring!$F$2:$F = end date

Thank you!

 

[RoryA]

You need to multiply the conditions:

=IFERROR(SUM(FILTER(Recurring!$C$2:$C,
    (B5 >= Recurring!$E$2:$E) * (B5 < Recurring!$F$2:$F) *
    (
        (Recurring!$G$2:$G = "Once") * (B5 = Recurring!$E$2:$E) +
        (Recurring!$G$2:$G = "Weekly") * (MOD(DAYS(B5, Recurring!$E$2:$E),7)=0)+
        (Recurring!$G$2:$G = "Monthly") * (DAY(B5)=DAY(Recurring!$E$2:$E))
    )
)),"")

 

[288enzo]

You need to multiply the conditions:

=IFERROR(SUM(FILTER(Recurring!$C$2:$C,
    (B5 >= Recurring!$E$2:$E) * (B5 < Recurring!$F$2:$F) *
    (
        (Recurring!$G$2:$G = "Once") * (B5 = Recurring!$E$2:$E) +
        (Recurring!$G$2:$G = "Weekly") * (MOD(DAYS(B5, Recurring!$E$2:$E),7)=0)+
        (Recurring!$G$2:$G = "Monthly") * (DAY(B5)=DAY(Recurring!$E$2:$E))
    )
)),"")

Fantastic, thank you for the assist.