Sum data with multiple criteria

[Katich]

Hello,
I know how to use the SUMIFS but for what i want to use it for, i feel i may need something else. My first sheet i have column D (MTD Actual) which i want to Sum all amounts that equal the account in column C and also reference the entity (B1). I'm able to get that to work. Now, i want to have in the formula so that whenever the month (B2) changes, it will find the column on my other tab and pull those totals. This way i don't need to change the lookup column each month.

Book2
	A	B	C	D	E	F	G
1	Entity	5860-xxxx
2	Month	Jan/25
3	Roll Up	Reporting Line	Account Description	MTD Actual	Adjustments	Budget	Variance
4	Operating Revenue	Sponsorship Revenue	401001-Sponsorship Income	-			-
5	Operating Revenue	Other Revenue	401003-Non-Tenant Income	-			-
6	Operating Revenue	Rental Revenue	401004-Lease Income	-			-
7	Operating Revenue	Other Revenue	401010-Other/Misc Income	83,858.90			83,858.90
8	Operating Revenue	Other Revenue	401030-Parking Revenue	-			-
9	Operating Revenue	Food & Beverage Revenue	401040-Banquet / Catering Revenue	-			-
10	Operating Revenue	Rental Revenue	401100-Tenant Base Rent	-			-
11	Operating Revenue	Reimbursements	401200-Tenant CAM	-			-
12	Operating Revenue	Reimbursements	401300-Tenant Insurance	-			-
13	Operating Revenue	Reimbursements	401400-Tenant Real Estate Tax	-			-
14	Operating Revenue	Other Revenue	401500-Tenant Percentage Rent	-			-
15	Operating Revenue	Reimbursements	401600-Tenant TDD Tax	-			-
16	Operating Revenue	Reimbursements	401700-Tenant CAT Tax	-			-
17	Operating Revenue	Rental Revenue	401800-Tenant Marketing Fee	-			-
18	Operating Revenue	Reimbursements	401900-Tenant Utility Reimbursement	-			-
19	Operating Revenue	Ticket Revenue	402001-Ticket Sales Revenue	-			-
20	Operating Revenue	Premium Seating	402010-Luxury Suites	-			-
DT

Cell Formulas
Range	Formula
D4:D20	D4	=SUMIFS('Income Statement - Accou'!$D$3:$D$1000,'Income Statement - Accou'!$A$3:$A$1000,DT!$B$1,'Income Statement - Accou'!$C$3:$C$1000,DT!C4)*-1
G4:G20	G4	=D4+E4-F4

Book2
	A	B	C	D	E
1	Income Statement - Account Balances - Report
2	Entity	Department	Account	Jan/25	Feb/25
43	5860-XXXX	000-Default Department	401010-Other/Misc Income	(83,858.90)	0.00
44	5860-XXXX	000-Default Department	502044-Propane/Gasoline	(127.74)	0.00
45	5860-XXXX	000-Default Department	505233-Food and Beverage Supplies	(415.31)	0.00
46	5860-XXXX	000-Default Department	508001-Retail Non-CAM Operating Expenses	5,352.83	(12,612.95)
47	5860-XXXX	000-Default Department	601031-Employee expense reimbursements	(2,838.93)	458.73
48	5860-XXXX	000-Default Department	601040-Payroll Taxes - Social Security	63.02	0.00
49	5860-XXXX	000-Default Department	602055-Office Supplies	74.54	0.00
50	5860-XXXX	000-Default Department	602070-Bank Service Charges	1,360.72	0.00
51	5860-XXXX	000-Default Department	602086-Employee Benefits	9,461.64	0.00
52	5860-XXXX	000-Default Department	700022-Amortization Expense	8,388.00	0.00
Income Statement - Accou

 

[Fluff]

How about

=-SUMIFS(INDEX('Income Statement - Accou'!$D$3:$Z$1000,,MATCH(b2,'Income Statement - Accou'!$D$2:$Z$2,0)),'Income Statement - Accou'!$A$3:$A$1000,$B$1,'Income Statement - Accou'!$C$3:$C$1000,C4)

 

[HongRu]

Try.

D4
=SUMIFS(INDEX('Income Statement - Accou'!$D$3:$E$1000,0,MATCH($B$2,'Income Statement - Accou'!$D$2:$E$2,0)),'Income Statement - Accou'!$A$3:$A$1000,DT!$B$1,'Income Statement - Accou'!$C$3:$C$1000,DT!C4)*-1

Copy it downward.

 

[Katich]

Thank you both!! I truly appreciate the assistance!

 

[Fluff]

Glad we could help & thanks for the feedback.