Sum cells, ignoring hidden columns

[sofas]

How can I calculate the sum of the following cells while ignoring the hidden columns?

=SUBTOTAL(109,E4,G4,I4,K4,M4,O4,Q4,S4)

 

[Sam_D_Ben]

Can you please post your data here.

Thanks

 

[sofas]

Can you please post your data here.

Thanks

test(2)

MediaFire is a simple to use free service that lets you put all your photos, documents, music, and video in a single place so you can access them anywhere and share them everywhere.

www.mediafire.com

 

[Sam_D_Ben]

test(2)

MediaFire is a simple to use free service that lets you put all your photos, documents, music, and video in a single place so you can access them anywhere and share them everywhere.

www.mediafire.com

I am sorry, not the link, i mean pasting your data here, thanks

 

[Dave Patton]

N.B. My suggestion does not consider the "hidden" part of the question.
It gives the sum whether of not the columns are hidden.

With Excel 365 and possibly 2021, try the following.
With earlier versions of Excel, use SumProduct.
Does your data include Headings?

T202401a.xlsm
	E		G		I		K		M		O		Q		S	T	U
4	2		6		10		14		18		22		26		30	128	128
1a

Cell Formulas
Range	Formula
T4	T4	=SUM(E4:S4*(--ISODD(COLUMN(E4:S4))))
U4	U4	=SUM(E4:S4*({1,0,1,0,1,0,1,0,1,0,1,0,1,0,1}))

 

[Dave Patton]

I haven't tested the Lambda

T202401a.xlsm
	E		G		I		K		M		O		Q		S	T	U
7	2		6		10		14		18		22		26		30	128	128
8
1a

Cell Formulas
Range	Formula
T7	T7	=SUM(IF(CELL("width",OFFSET(E7:S7,,SEQUENCE(,COLUMNS(E7:S7),0))),E7:S7))
U7	U7	=SumNotHiddenColumn(E7:S7)

Lambda Functions
Name	Formula
SumNotHiddenColumn	=LAMBDA(rColsHidden,LET(rH,rColsHidden,SUM(IF(CELL("width",OFFSET(rH,,SEQUENCE(,COLUMNS(rH),0))),rH))))

 

[Dave Patton]

For earlier versions of Excel, try the following.
I do not know if the formula works with Excel 2019.
The Lambda suggestion requires Excel 365.

T202401a.xlsm
	E		G		I		K		M		O		Q		S	T	U
4	2		6		10		14		18		22		26		30	128	128
1a

Cell Formulas
Range	Formula
T4	T4	=SUMPRODUCT(E4:S4,--ISODD(COLUMN(E4:S4)))
U4	U4	=SUMPRODUCT(E4:S4*({1,0,1,0,1,0,1,0,1,0,1,0,1,0,1}))

 

[Dave Patton]

If columns are hidden or unhidden, we must force a recalculation to secure the correct result. Use F9.

T202401a.xlsm
	E	F	G													T	U	V	W
3																Odd	Odd
4	1	2	3													64	64	6	6
5
1a

Cell Formulas
Range	Formula
T4	T4	=SUMPRODUCT(E4:S4,--ISODD(COLUMN(E4:S4)))
U4	U4	=SUMPRODUCT(E4:S4*({1,0,1,0,1,0,1,0,1,0,1,0,1,0,1}))
V4	V4	=LET(rng,E4:S4,SUM(--(CELL("width",OFFSET(rng,,SEQUENCE(,COLUMNS(rng),0)))>0)*rng))
W4	W4	=SumNot(E4:S4)

Lambda Functions
Name	Formula
SumNot	=LAMBDA(rngColumns,LET(rCols,rngColumns,SUM(--(CELL("width",OFFSET(rCols,,SEQUENCE(,COLUMNS(rCols),0)))>0)*rCols)))

T202401a.xlsm
	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W
3																Odd	Odd
4	1	2	3	4	5	6	7	8	9	10	11	12	13	14	15	64	64	120	120
1a

Cell Formulas
Range	Formula
T4	T4	=SUMPRODUCT(E4:S4,--ISODD(COLUMN(E4:S4)))
U4	U4	=SUMPRODUCT(E4:S4*({1,0,1,0,1,0,1,0,1,0,1,0,1,0,1}))
V4	V4	=LET(rng,E4:S4,SUM(--(CELL("width",OFFSET(rng,,SEQUENCE(,COLUMNS(rng),0)))>0)*rng))
W4	W4	=SumNot(E4:S4)

Lambda Functions
Name	Formula
SumNot	=LAMBDA(rngColumns,LET(rCols,rngColumns,SUM(--(CELL("width",OFFSET(rCols,,SEQUENCE(,COLUMNS(rCols),0)))>0)*rCols)))