Sum 2 columns on every Ws (except 3)and if they are equal to each other change their fill color

[JakariKryze]

I need to get my code to Sum 2 columns on every Ws and if they are equal to each other change their fill color. i need to do this for 40 sheets but i have 3 sheets this doesnt need to happen for.
My current code only does the Sum for the active sheet i am on and i havent been able to get the color to work:

Sub EveryDaySum()
Dim Ws As Worksheet
For Each Ws In Worksheets
 Range("E1").Select
    ActiveCell.FormulaR1C1 = "=SUM(R[1]C:R[7]C)"
    Range("J1").Select
    ActiveCell.FormulaR1C1 = "=SUM(R[1]C:R[2]C)"
If Cell.Value("E1") = ("J1") Then Range("E1,J1").Select
    Range("J1").Activate
    With Selection.Interior 'Color Yellow
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = 65535
        .TintAndShade = 0
        .PatternTintAndShade = 0
        Selection.Font.Bold = True
    End With
    End IF
    Next Ws
End Sub

 

[Micron]

The error message and the line that triggers it is usually a must. That code shouldn't run or compile - you have an extra End If there. Where is this code, at the workbook level, sheet, or module?
Also, would you not have to activate a sheet before you can select a range if you're wanting this code to loop over sheets?
You also need a test (If / End If block) to weed out the sheets you don't want the code to act on.

 

[Micron]

I have a version that works but you'll need to provide some answers first. It depends on where your code is.

 

[Peter_SSs]

You could try this (after editing it for the names of the 3 sheets that you don't want it to act on) with a copy of your workbook.

Sub EveryDaySum_v2()
  Dim Ws As Worksheet
  
  For Each Ws In Worksheets
    With Ws
      Select Case .Name
        Case "Sheet1", "Sheet2", "Sheet3"   '<- Names of sheets you want to skip
        Case Else
          .Range("E1").FormulaR1C1 = "=SUM(R[1]C:R[7]C)"
          .Range("J1").FormulaR1C1 = "=SUM(R[1]C:R[2]C)"
          If .Range("E1").Value = .Range("J1").Value Then
            With .Range("E1, J1")
              .Font.Bold = True
              .Interior.Color = 65535
            End With
          End If
      End Select
    End With
  Next Ws
End Sub