Subtract the numeric values of 2 Textboxes

[Denny57]

I am trying to populate a text box in a user form with the result of the subtraction of the values of 2 other text boxes.

Similar code works when the format of the textboxes are currency

Private Sub EndReadingDay_AfterUpdate()

    Dim c As Double, d As Double
    c = txtStartReadingDay.Value
    d = txtEndReadingDay.Value
    
    txtUnitsUsedDay.Value = Format(Val(d - c, "#,##0.0"))
       
End Sub

NOTE: the Textboxes have a maximum of 6 characters and the values are to one decimal place

Thank you in advance

 

[Joe4]

Try changing this line:

    txtUnitsUsedDay.Value = Format(Val(d - c, "#,##0.0"))

to this:

    txtUnitsUsedDay.Value = Format(Val(d) - Val(c), "#,##0.0")

 

[DanteAmor]

I'm not sure about the names of your textboxes, but try this, just check the names of the textboxes and your event EndReadingDay_AfterUpdate

Private Sub EndReadingDay_AfterUpdate()
    Dim c As Double, d As Double
    
    If txtStartReadingDay.Value <> "" Then
      c = CDbl(txtStartReadingDay.Value)
    End If
    If txtEndReadingDay.Value <> "" Then
      d = txtEndReadingDay.Value
    End If
    
    txtUnitsUsedDay.Value = Format(d - c, "#,##0.0")
       
End Sub

 

[Denny57]

Unfortunately both solutions do not complete the required action. The details are meter readings both to 1 decimal place.
I was hoping to populate the difference between the start and end textbox values into the txtUnitsUsedDay textbox.

By using AfterUpdate (as I have used previously and which works in other areas of the full code as well as in other files) I was trusting the difference to be automatically populated into the txtUnitsUsedDay textbox as soon as both the other textboxes are populated.

This is not happening and I am confused why this mighe be the case.

 

[DanteAmor]

Unfortunately both solutions do not complete the required action.

...

I'm not sure about the names of your textboxes

Apparently the names of your textboxes are:

txtStartReadingDay and txtEndReadingDay

the txtUnitsUsedDay textbox as soon as both the other textboxes are populated.

According to the above, the event must be Change.

Replace your code with the following:

Private Sub txtEndReadingDay_Change()
  Call Procedure_update_txtUnitsUsedDay
End Sub

Private Sub txtStartReadingDay_Change()
  Call Procedure_update_txtUnitsUsedDay
End Sub

Private Sub Procedure_update_txtUnitsUsedDay()
  Dim c As Double, d As Double
 
  If txtStartReadingDay.Value <> "" Then
    c = CDbl(txtStartReadingDay.Value)
  End If
  If txtEndReadingDay.Value <> "" Then
    d = CDbl(txtEndReadingDay.Value)
  End If

  txtUnitsUsedDay.Value = Format(d - c, "#,##0.0")
End Sub

In the future, it would be ideal if you put all your code, that way we help you with a better solution. Otherwise, we will assume that with a simple idea, you will be able to adapt it to your code.