Substitute all letters for "" until first number from the right

[cdalgorta]

Hi,
So basically I have 4 main possibilities:
PYMT769291
INV 769291
INV 769291_1 -> This could be _2 or _3 or _4...
INV 769291BD

And I need 1 formula that makes them all convert into this:
PYMT769291 -> This one should never change
769291 -> This one gets rid of the "INV "
769291 -> This one gets rid of the "INV " & everything after "_"
769291 -> This one gets rid of the "INV " & the 2 letters at the end

So far I have this:
=IFERROR(LEFT(SUBSTITUTE(A1,"INV ",""),FIND("_",SUBSTITUTE(A1,"INV ",""))-1),SUBSTITUTE(A1,"INV ",""))
And I get the following:
PYMT769291
769291
769291
769291BD

I do not know what formula to use to delete the letters at the end of the last one "without" changing the other 3 which are already as I want them to show. Basically a formula that will only delete letters on the right up to the first number it finds, and if it doesn't find any letters, then it gives back the original. Any ideas? I'm a novice, so apologies if my question is too easy for you hahah.

Thank you very much in advance!
Cristian

 

[Rick Rothstein]

Is the number that you want to retrieve from the INV cells always 6 digits long?

 

[cdalgorta]

Is the number that you want to retrieve from the INV cells always 6 digits long?

Hi Rick,
It is not. As of now, it goes up to 7 digits and it will probably reach 8 digits by next year.

 

[Rick Rothstein]

Give this formula a try...

=IF(LEFT(A1,4)="PYMT",A1,LOOKUP(9.9E+307,--LEFT(MID(A1,5,9),ROW($1:$99))))

 

[Rick Rothstein]

Give this formula a try...

=IF(LEFT(A1,4)="PYMT",A1,LOOKUP(9.9E+307,--LEFT(MID(A1,5,9),ROW($1:$99))))

Actually, since you are using XL2021, this would be better...

=IF(LEFT(A1,4)="PYMT",A1,LOOKUP(9.9E+307,--LEFT(MID(A1,5,9),SEQUENCE(99))))

 

[cdalgorta]

Give this formula a try...

=IF(LEFT(A1,4)="PYMT",A1,LOOKUP(9.9E+307,--LEFT(MID(A1,5,9),ROW($1:$99))))

To me, you are a genius hahah. It worked perfectly. Thank you so much Rick! You are a the real MVP!

Could I kindly ask you to explain to me how this formula works though? So I can learn hahah
What does "LOOKUP(9.9E+307..." do?
And what is the "ROW($1:$99)" for? The data that I ran for testing has over 2000 rows and this "ROW($1:$99)" still works. What does it do?
Thank you in advance!

 

[cdalgorta]

Actually, since you are using XL2021, this would be better...

=IF(LEFT(A1,4)="PYMT",A1,LOOKUP(9.9E+307,--LEFT(MID(A1,5,9),SEQUENCE(99))))

Thank you for reminding me that I had to change that hahah. I have 365 actually. Just changed my profile. No idea what the difference is yet, but based on this reply, seems like there are some formulas that are better to use depending on the Excel you have. Good to know hahah.