Sub for keypress check

[Latexy]

Hi!

Well i have a question for check keypress for multiple textbox with public sub.
Heres example how i have done it now for each textbox.

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    KeyAscii = KeyAscii * -CLng(Chr(KeyAscii) Like "[0-9]")
End Sub

So i would like to make one sub wich to call for keypress check.

-Late

 

[DanteAmor]

Put the following code in userform

Dim TxtBx() As New Class1  [COLOR=#008000]'At the beginning of all the code[/COLOR]


Private Sub UserForm_Initialize()
  Dim i As Long, n As Long, ctrl As MSForms.Control
  i = 1
  For Each ctrl In Me.Controls
    If TypeName(ctrl) = "TextBox" Then
      ReDim Preserve TxtBx(i)
      Set TxtBx(i).MultTextbox = ctrl
      i = i + 1
    End If
  Next
End Sub

------------------------------------------
Insert a class module "Class1"
Put the following code in Class1

Public WithEvents MultTextbox As MSForms.TextBox    [COLOR=#008000]'At the beginning of all the code[/COLOR]


Private Sub MultTextbox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
  KeyAscii = KeyAscii * -CLng(Chr(KeyAscii) Like "[0-9]")
End Sub

 

[Latexy]

Thank you!
One more thing i noticed is there should be possible to write comma to make value with desimals. Can you help with it?

-Late

 

[DanteAmor]

Use this in class module

Public WithEvents MultTextbox As MSForms.TextBox


Private Sub MultTextbox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
  If Not (KeyAscii >= 48 And KeyAscii <= 57) And KeyAscii <> 44 Then
    KeyAscii = 0
  End If
End Sub

 

[Latexy]

Thank you very much!
Nice to get help because im just beginner of coding and learning it while trying to make some simple workbooks

-Late

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.