STREAK

[Xlambda]

STREAK Largest consecutive distribution of a given value, byrow or bycol
This is my take on a cool function: STREAK
Added new functionality, max argument [x]
Main calculation core of the function: IF(i, v + i, 0)

=LAMBDA(a, v, [o], [x],
    LET(
        b, IF(a = v, 1, 0),
        s, LAMBDA(x, MAX(SCAN(0, x, LAMBDA(v, i, IF(i, v + i, 0))))),
        i, IF(o, BYROW(b, LAMBDA(x, s(x))), BYCOL(b, LAMBDA(x, s(x)))),
        IF(x, MAX(i), i)
    )
)

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC
1
2		=CHAR(RANDARRAY(20,20,65,67,1))																					=STREAK(B3#,"a")
3		C	C	B	A	B	A	B	C	B	C	B	C	A	B	C	A	B	C	B	A		1
4		A	A	A	B	B	A	A	A	B	C	B	C	A	B	A	B	A	C	B	A		3
5		A	C	C	B	C	B	B	B	B	A	B	B	C	B	A	B	C	B	C	C		1
6		B	A	B	C	A	B	A	B	C	A	A	A	B	A	C	A	A	A	B	A		3
7		A	C	A	A	A	C	C	C	C	B	A	A	B	C	B	B	A	B	C	B		3
8		C	A	C	C	A	B	A	C	B	B	B	B	B	C	C	C	A	B	C	B		1
9		C	C	A	A	C	B	A	A	A	A	B	C	A	A	A	B	B	A	C	C		4
10		B	A	A	C	B	A	C	A	A	B	C	C	B	A	A	A	B	C	C	C		3
11		B	B	A	B	B	C	C	A	B	B	B	A	B	A	B	A	B	A	C	A		1
12		A	B	C	A	A	A	C	A	C	A	C	B	C	A	A	B	A	B	C	A		3
13		C	C	C	B	C	C	A	A	A	B	C	A	B	C	A	A	C	A	B	A		3
14		B	C	C	B	A	A	A	A	C	A	B	C	A	A	B	B	A	A	A	B		4
15		B	C	B	A	B	B	A	A	A	B	C	A	B	B	C	A	A	A	C	B		3
16		B	B	A	C	B	A	C	A	B	B	A	A	B	A	C	B	A	B	B	B		2
17		B	B	B	A	B	A	B	A	B	A	B	B	C	C	C	B	B	A	A	A		3
18		B	B	B	A	B	B	A	C	B	B	C	C	C	A	C	B	C	A	B	C		1
19		A	A	A	B	A	B	B	A	B	C	C	C	C	A	B	C	B	A	C	C		3
20		A	A	C	A	A	B	A	B	B	A	B	C	B	A	A	C	A	C	A	C		2
21		C	B	A	A	B	A	A	A	B	A	C	B	B	C	A	A	B	B	C	B		3		=STREAK(B3#,"a",,1)
22		B	B	A	B	C	A	A	C	A	C	A	C	C	C	A	A	B	A	A	C		2		4
23
24		2	2	3	2	3	2	3	9	2	2	2	2	2	4	3	2	3	3	1	3
25		=STREAK(B3#,"a",1)
26																					9
27																					=STREAK(B3#,"a",1,1)
28
Sheet1

Cell Formulas
Range	Formula
B2,Y21,W2	B2	=FORMULATEXT(B3)
B3:U22	B3	=CHAR(RANDARRAY(20,20,65,67,1))
W3:W22	W3	=STREAK(B3#,"a")
Y22	Y22	=STREAK(B3#,"a",,1)
B24:U24	B24	=STREAK(B3#,"a",1)
B25,U27	B25	=FORMULATEXT(B24)
U26	U26	=STREAK(B3#,"a",1,1)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B3:U22	Expression	=B3="a"	text	NO

 

[st001]

I wonder, if instead of providing an argument "a", one could optionally also leave that out, and it returns the frequency distribution as an array, (instead of a vector), either by row, or by column?

 

[st001]

I think BYCOL and BYROW are the wrong way round - below is my edit. I've also replaced the last argument from x, to m, for readability, since the inner lambdas have their own 'x'...

STREAK = LAMBDA(a, v, [o], [m],
    LET(
        b, IF(a = v, 1, 0),
        s, LAMBDA(x, MAX(SCAN(0, x, LAMBDA(v, i, IF(i, v + i, 0))))),
        i, IF(o, BYCOL(b, LAMBDA(x, s(x))), BYROW(b, LAMBDA(x, s(x)))),
        IF(m, MAX(i), i)
    )
);

 

[Xlambda]

Yes st001, you are right !! They were switched. Thank you!!
Regarding max I am sticking with "x", intuitively I am using m for min and x for max.
And there is no problem with "x", inside closed LAMBDAS arguments can take any other previous variable name.

=LAMBDA(a, v, [o], [x],
    LET(
        b, IF(a = v, 1, 0),
        s, LAMBDA(x, MAX(SCAN(0, x, LAMBDA(v, i, IF(i, v + i, 0))))),
        i, IF(o, BYCOL(b, LAMBDA(x, s(x))), BYROW(b, LAMBDA(x, s(x)))),
        IF(x, MAX(i), i)
    )
)

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC
1
2		=CHAR(RANDARRAY(20,20,65,67,1))																					=STREAK(B3#,"a")
3		B	A	A	A	A	B	B	A	C	A	A	A	A	A	A	A	B	B	B	B		7
4		B	B	C	B	B	A	A	C	B	B	A	B	C	C	A	C	B	B	B	A		2
5		B	C	A	C	C	C	C	C	B	C	A	B	A	C	C	A	C	B	C	C		1
6		B	A	C	A	A	A	C	A	B	A	C	C	B	C	A	C	C	A	B	B		3
7		C	B	B	C	C	B	A	B	B	C	B	A	C	A	A	C	A	C	C	B		2
8		A	C	A	C	A	C	A	B	B	A	B	C	A	B	C	C	A	B	A	C		1
9		B	C	A	B	B	A	A	C	B	A	B	B	A	C	A	A	A	A	B	C		4
10		C	A	B	C	A	C	A	A	C	A	C	B	C	B	C	A	C	A	A	A		3
11		B	B	A	A	A	C	A	C	C	C	A	C	B	C	B	C	A	A	C	B		3
12		B	B	B	B	A	A	C	B	A	C	A	B	C	B	C	C	A	C	C	B		2
13		A	C	C	C	C	C	B	A	B	B	A	A	B	A	A	A	B	A	C	B		3
14		B	B	C	B	B	A	A	A	B	A	A	C	B	C	A	C	A	C	A	A		3
15		A	C	A	C	B	A	C	A	C	C	B	C	C	A	C	C	A	A	B	C		2
16		C	A	A	B	B	A	C	C	B	B	B	A	C	B	A	C	A	B	C	C		2
17		C	A	B	C	C	C	B	A	B	C	A	A	C	A	A	A	B	C	C	C		3
18		A	A	C	A	C	C	B	A	B	A	C	A	A	A	A	A	A	A	B	C		7
19		B	A	B	C	C	B	B	B	A	B	C	A	C	C	A	B	C	B	A	C		1
20		C	C	A	B	B	B	C	B	B	C	B	A	C	A	C	A	A	C	A	B		2
21		B	B	C	B	C	A	B	B	B	A	A	C	C	B	C	C	C	A	C	C		2		=STREAK(B3#,"a",,1)
22		C	C	A	A	B	B	B	A	C	C	A	C	B	A	C	B	A	C	B	B		2		7
23
24		1	4	2	1	3	3	5	3	1	3	4	5	2	2	4	2	3	3	2	1
25		=STREAK(B3#,"a",1)
26																					5
27																					=STREAK(B3#,"a",1,1)
28
Sheet1

Cell Formulas
Range	Formula
B2,Y21,W2	B2	=FORMULATEXT(B3)
B3:U22	B3	=CHAR(RANDARRAY(20,20,65,67,1))
W3:W22	W3	=STREAK(B3#,"a")
Y22	Y22	=STREAK(B3#,"a",,1)
B24:U24	B24	=STREAK(B3#,"a",1)
B25,U27	B25	=FORMULATEXT(B24)
U26	U26	=STREAK(B3#,"a",1,1)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B3:U22	Expression	=B3="a"	text	NO

 

[Xlambda]

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V
1		Concept for an alternative solution, very versatile, delivers all information about streaks lenghts and their frequencies with ease
2		Works for arrays < 32,767rws x 32,767clms (CONCAT Excel limit)
3
4		sample vector
5		B	A	A	A		A	A		A	A	A		A	A	A	A		A	A	C
6
7		=--(B5:U5="a")
8		0	1	1	1	0	1	1	0	1	1	1	0	1	1	1	1	0	1	1	0
9
10		=CONCAT(B8#)
11		01110110111011110110
12
13		=TEXTSPLIT(B11,0,,1)
14		111	11	111	1111	11
15
16		=LEN(B14#)
17		3	2	3	4	2		all information about frequencies/lengths is here.
18								2x2 elements
19								2x3 elements
20								1x4 elements
21
22		Based on that we can develop any function we want to do any more or less complex analysis we want only with some arrays cosmetics.
23
Sheet2

Cell Formulas
Range	Formula
B7,B16,B13,B10	B7	=FORMULATEXT(B8)
B8:U8	B8	=--(B5:U5="a")
B11	B11	=CONCAT(B8#)
B14:F14	B14	=TEXTSPLIT(B11,0,,1)
B17:F17	B17	=LEN(B14#)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B5:U5	Expression	=B5="a"	text	NO

 

[Xlambda]

Extracting only max frequencies is too simple.
There are 2 important parameters when it comes to a complete study of streaks distributions, their lengths, and their frequencies.
This function returns the frequency distribution for each streak's length.
STREAKS(ar,[v],[o]) (2 embedded lambdas and 1 REDUCE to assemble the results)
ar: array
[v]: single value or array of values, if omitted, all unique values of "ar" are considered
[o]: orientation, if omitted, byrow, if 1, bycol

=LAMBDA(ar, [v], [o],
    LET(
        a, IF(ar = "", "", ar),
        u, SORT(UNIQUE(TOCOL(a))),
        s, LAMBDA(x, LET(s, SCAN(0, x, LAMBDA(v, i, IF(i, v + i, 0))), f, FILTER(s, s), q, FREQUENCY(f, SEQUENCE(MAX(f))), TEXTJOIN(",", , DROP(q, -1) - DROP(q, 1)))),
        r, LAMBDA(x, LET(e, --(a = x), IF(o, BYCOL(e, LAMBDA(x, s(x))), BYROW(e, LAMBDA(x, s(x)))))),
        b, IF(ISOMITTED(v), u, TOCOL(v)),
        d, REDUCE(0, SEQUENCE(ROWS(b)), LAMBDA(v, i, LET(x, INDEX(b, i), IF(o, VSTACK(v, r(x)), HSTACK(v, r(x)))))),
        IFERROR(IF(o, HSTACK(b, DROP(d, 1)), VSTACK(TOROW(b), DROP(d, , 1))), 0)
    )
)

STREAK.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF
1		"o", omitted => streaks byrow																					v,omitted=> all values
2																							=STREAKS(B4:U23)				=STREAKS(B4:U23,{"C","B"})			=STREAKS(B4:U23,"A")
3		ar																					A	B	C		C	B		A
4		A	B	B	A	A	B	C	B	C	B	C	B	C	B	C	A	C	B	B	B		2,1	5,1,1	6		6	5,1,1		2,1
5		C	A	B	B	C	C	C	B	A	C	B	B	A	A	B	C	A	B	C	B		3,1	4,2	4,0,1		4,0,1	4,2		3,1
6		A	B	A	A	B	C	C	C	A	B	C	B	B	A	C	A	B	C	A	A		4,2	4,1	3,0,1		3,0,1	4,1		4,2
7		A	A	A	A	C	A	A	C	C	B	B	A	C	A	C	C	B	B	A	C		3,1,0,1	0,2	3,2		3,2	0,2		3,1,0,1
8		B	A	C	B	B	C	B	B	A	B	B	C	C	B	C	A	B	B	B	C		3	2,3,1	4,1		4,1	2,3,1		3
9		A	A	A	C	C	A	A	A	A	A	B	B	B	A	C	A	B	A	A	A		2,0,2,0,1	1,0,1	1,1		1,1	1,0,1		2,0,2,0,1
10		A	B	B	B	B	C	C	B	B	B	B	A	A	C	C	C	C	B	A	C		2,1	1,0,0,2	1,1,0,1		1,1,0,1	1,0,0,2		2,1
11		A	C	C	B	B	A	C	B	B	B	C	B	A	B	C	A	A	B	A	B		4,1	4,1,1	3,1		3,1	4,1,1		4,1
12		C	A	C	C	B	C	A	B	C	C	A	C	A	C	B	C	B	C	C	B		4	5	5,3		5,3	5		4
13		A	A	B	C	A	C	C	A	C	B	C	C	A	A	B	B	A	B	A	B		4,2	4,1	2,2		2,2	4,1		4,2
14		B	A	C	C	C	C	A	A	A	C	C	C	A	A	B	B	C	B	C	A		2,1,1	2,1	2,0,1,1		2,0,1,1	2,1		2,1,1
15		B	C	A	A	C	C	C	B	B	B	B	C	B	B	A	B	B	A	C	A		3,1	1,2,0,1	3,0,1		3,0,1	1,2,0,1		3,1
16		B	C	A	B	B	B	B	B	B	C	C	B	B	C	B	C	B	B	C	C		1	2,2,0,0,0,1	3,2		3,2	2,2,0,0,0,1		1
17		B	A	A	B	C	A	A	C	B	A	B	A	B	B	C	C	C	A	C	A		4,2	4,1	3,0,1		3,0,1	4,1		4,2
18		B	A	B	A	B	A	A	A	A	C	A	B	C	C	A	C	B	A	B	C		5,0,0,1	6	3,1		3,1	6		5,0,0,1
19		B	B	C	A	A	B	A	A	B	C	C	B	C	A	B	B	B	B	B	C		1,2	3,1,0,0,1	3,1		3,1	3,1,0,0,1		1,2
20		C	B	C	A	A	B	A	C	B	A	A	B	B	C	C	B	B	B	B	B		1,2	3,1,0,0,1	3,1		3,1	3,1,0,0,1		1,2
21		C	B	C	C	B	A	B	B	B	A	A	A	B	B	B	C	C	B	A	C		2,0,1	3,0,2	2,2		2,2	3,0,2		2,0,1
22		C	C	B	C	B	B	C	C	A	C	C	C	C	A	A	A	B	A	A	B		1,1,1	3,1	1,2,0,1		1,2,0,1	3,1		1,1,1
23		B	C	B	C	A	B	A	B	A	C	C	B	C	C	A	B	B	A	B	C		5	6,1	3,2		3,2	6,1		5
24
25																							Results interpretation
26
27																							2,0,2,0,1		2 "A" streaks of len=1
28																									0 "A" streaks of len=2
29																									2 "A" streaks of len=3
30																									0 "A" streaks of len=4
31																									1 "A" streak of len=5
32
STREAKS 1

Cell Formulas
Range	Formula
W2,AA2,AD2	W2	=FORMULATEXT(W3)
W3:Y23	W3	=STREAKS(B4:U23)
AA3:AB23	AA3	=STREAKS(B4:U23,{"C","B"})
AD3:AD23	AD3	=STREAKS(B4:U23,"A")
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B4:U23	Expression	=B4="c"	text	NO
B4:U23	Expression	=B4="b"	text	NO
B4:U23	Expression	=B4="a"	text	NO

 

[Xlambda]

STREAK.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M
1		"o",1, streaks bycol
2		=STREAKS(C15:L44,,1)
3		A	2,2,1,1	5,1,1	4,2	5,1,1	6,0,1	3,4	8,1	3,1,2	3,1,0,0,1	5,2
4		B	2,3	2,4	1,1,1,1	5,2	5,1,1	4,0,1	6,1	2,2,0,1	4,2,1	4,2,1
5		C	5,0,0,1	6,2	1,3,0,0,1	3,4	3,4	3,3,1	5,2,1	4,1,1	5,0,0,1	1,3,1
6
7		=STREAKS(C15:L44,{"C","B"},1)
8		C	5,0,0,1	6,2	1,3,0,0,1	3,4	3,4	3,3,1	5,2,1	4,1,1	5,0,0,1	1,3,1
9		B	2,3	2,4	1,1,1,1	5,2	5,1,1	4,0,1	6,1	2,2,0,1	4,2,1	4,2,1
10
11		=STREAKS(C15:L44,"A",1)
12		A	2,2,1,1	5,1,1	4,2	5,1,1	6,0,1	3,4	8,1	3,1,2	3,1,0,0,1	5,2
13
14
15		ar	C	B	C	C	A	A	A	C	B	B
16			C	B	C	B	C	A	B	C	C	B
17			C	A	A	A	C	C	A	C	B	A
18			C	C	A	A	A	C	B	B	B	C
19			A	B	B	C	B	A	C	B	C	C
20			A	C	A	A	C	A	C	C	B	B
21			B	B	C	B	C	B	A	A	C	B
22			B	B	C	B	A	A	C	C	C	B
23			C	C	C	A	B	B	B	A	C	A
24			A	C	C	C	C	C	A	B	C	A
25			A	A	C	B	A	A	A	B	A	B
26			A	A	A	B	C	C	B	B	C	C
27			A	C	C	C	B	B	C	B	A	C
28			C	A	C	C	B	C	C	A	A	C
29			B	B	A	A	A	C	A	A	A	A
30			B	C	A	B	B	A	C	A	A	B
31			C	B	B	C	B	A	B	C	A	C
32			A	B	B	C	B	C	B	C	B	C
33			B	A	C	A	A	C	A	A	C	A
34			A	C	B	A	A	A	C	A	A	A
35			A	A	B	A	A	A	A	B	B	B
36			A	B	B	C	C	B	C	A	B	B
37			B	B	B	C	B	C	B	A	A	C
38			C	A	A	B	C	B	A	A	B	C
39			B	A	C	A	C	B	C	B	A	B
40			B	A	C	B	A	B	C	B	A	A
41			A	C	B	C	B	C	C	C	B	B
42			C	C	B	C	C	C	A	A	B	A
43			A	A	B	A	C	C	C	B	B	C
44			A	C	A	B	B	A	B	C	C	A
45
STREAKS 2

Cell Formulas
Range	Formula
B2,B11,B7	B2	=FORMULATEXT(B3)
B3:L5	B3	=STREAKS(C15:L44,,1)
B8:L9	B8	=STREAKS(C15:L44,{"C","B"},1)
B12:L12	B12	=STREAKS(C15:L44,"A",1)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
C15:L44	Expression	=C15="c"	text	NO
C15:L44	Expression	=C15="b"	text	NO
C15:L44	Expression	=C15="a"	text	NO

 

[Xlambda]

Extracting data from STREAKS 4D array(values, byrow, lengths, frequencies)
ROWSTREAK(a,[v],[n],[lf]) Calls STREAKS
a: array
[v]: single value or array of values, if omitted, all unique values of "ar" are considered
[n]: numeric value length/frequency, if omitted max(length)/max(frequency) triggered by "lf" argument
[lf]: length/frequency argument, if omitted=> frequencies, if 1=> lengths, if n=0 and lf=2=>lengths of max frequencies

=LAMBDA(a, [v], [n], [lf],
    LET(
        b, STREAKS(a, v),
        m, MAP(
            DROP(b, 1),
            LAMBDA(x,
                LET(
                    f, --TEXTSPLIT(x, ","),
                    y, MAX(f),
                    ml, COLUMNS(f),
                    l, SEQUENCE(, ml),
                    IF(n, IF(lf, INDEX(f, n), TEXTJOIN(",", , IF(f = n, l, ""))), IF(lf, IF(lf = 1, ml, y & ";" & XMATCH(y, f)), y))
                )
            )
        ),
        e, IFERROR(VSTACK(TAKE(b, 1), m), 0),
        IFERROR(--e, e)
    )
)

STREAK.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG	AH	AI	AJ	AK	AL	AM	AN	AO	AP
1
2		defined name "ar" = B4:AO8
3
4	ar	A	B	C	A	A	A	B	C	A	A	A	A	C	C	B	C	B	C	B	A	B	B	B	A	C	A	A	A	C	A	C	B	C	A	B	C	A	C	A	C
5		A	A	B	B	A	C	B	C	B	B	C	C	C	B	A	A	B	C	B	B	C	C	C	C	A	B	A	A	B	A	C	B	C	A	A	C	C	A	B	B
6		A	B	C	A	B	A	A	B	C	A	A	A	B	C	C	C	A	B	A	A	A	C	C	C	A	C	A	A	B	A	C	A	B	B	B	A	B	A	A	B
7		C	C	C	B	A	A	B	C	A	B	B	B	B	C	A	B	A	C	B	C	A	B	C	C	C	C	A	B	C	A	C	C	A	C	B	B	A	B	C	A
8		A	B	B	C	C	B	C	C	A	A	B	B	B	B	A	A	A	B	B	A	C	A	B	B	B	C	C	B	A	C	C	B	A	B	A	C	A	A	A	B
9
ROWSTREAK

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B4:AO8,AW4:AW8	Expression	=B4="c"	text	NO
B4:AO8,AW4:AW8	Expression	=B4="b"	text	NO
B4:AO8,AW4:AW8	Expression	=B4="a"	text	NO

 

[Xlambda]

STREAK.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1						all values, max frequencies					all values, max lengths					all values, max frequencies and their lengths
2						v, omitted=>all values					v, omitted=>all values					v, omitted=>all values
3						n, omitted,max					n, omitted,max					n, omitted,max
4						lf, omitted=> frequencies					lf,1=> lengths					lf,2=> max frequencies; min corespondent lengths
5		=STREAKS(ar)				=ROWSTREAK(ar)					=ROWSTREAK(ar,,,1)					=ROWSTREAK(ar,,,2)
6		A	B	C		A	B	C			A	B	C			A	B	C
7		7,0,2,1	7,0,1	11,1		7	7	11			4	3	2			7;1	7;1	11;1
8		4,4	6,4	5,1,1,1		4	6	5			2	2	4			4;1	6;1	5;1
9		7,3,2	8,0,1	4,0,2		7	8	4			3	3	3			7;1	8;1	4;1
10		9,1	7,1,0,1	7,1,1,1		9	7	7			2	4	4			9;1	7;1	7;1
11		6,1,2	5,2,1,1	2,4		6	5	4			3	4	2			6;1	5;1	4;2
12
13						lengths for frequencies=1					frequencies for length=1
14						v, omitted=>all values					v, omitted=>all values
15						n, 1					n, 1
16						lf, omitted=> frequencies					lf,1=> lengths
17						=ROWSTREAK(ar,,1)					=ROWSTREAK(ar,,1,1)
18						A	B	C			A	B	C
19						4	3	2			7	7	11
20								2,3,4			4	6	5
21							3				7	8	4
22						2	2,4	2,3,4			9	7	7
23						2	3,4				6	5	2
24
25						lengths for frequencies=2					frequencies for length=2
26						v, omitted=>all values					v, omitted=>all values
27						n, 2					n, 2
28						lf, omitted=> frequencies					lf,1=> lengths
29						=ROWSTREAK(ar,,2)					=ROWSTREAK(ar,,2,1)
30						A	B	C			A	B	C
31						3					0	0	1
32											4	4	1
33						3		3			3	0	0
34											1	1	1
35						3	2	1			1	2	4
36
37						lengths for frequencies=4					frequencies for length=4
38						v, omitted=>all values					v, omitted=>all values
39						n, 4					n, 4
40						lf, omitted=> frequencies					lf,1=> lengths
41						=ROWSTREAK(ar,,4)					=ROWSTREAK(ar,,4,1)
42						A	B	C			A	B	C
43											1	0	0
44						1,2	2				0	0	1
45								1			0	0	0
46											0	1	1
47								2			0	1	0
48
ROWSTREAK 1

Cell Formulas
Range	Formula
B5,K41,F41,K29,F29,K17,F17,P5,K5,F5	B5	=FORMULATEXT(B6)
B6:D11	B6	=STREAKS(ar)
F6:H11	F6	=ROWSTREAK(ar)
K6:M11	K6	=ROWSTREAK(ar,,,1)
P6:R11	P6	=ROWSTREAK(ar,,,2)
F18:H23	F18	=ROWSTREAK(ar,,1)
K18:M23	K18	=ROWSTREAK(ar,,1,1)
F30:H35	F30	=ROWSTREAK(ar,,2)
K30:M35	K30	=ROWSTREAK(ar,,2,1)
F42:H47	F42	=ROWSTREAK(ar,,4)
K42:M47	K42	=ROWSTREAK(ar,,4,1)
Dynamic array formulas.

Named Ranges
Name	Refers To	Cells
ar	=ROWSTREAK!$B$4:$AO$8	B6, F6, F18, F30, F42, K6, K18, K30, K42, P6

 

[st001]

Sublime work XLambda!
I am kind of thinking that cell P8, should be: 4; 1, 2 - for joint maxes?