Spreading Values while dates....

[Dclem]

I have been trying to figure out a formula to show how many days a project would take if a start date was given and hours of project assuming a person worked 8 hrs per day. See example below. I used the formula
MIN(D$3-SUM($F$3:G3),8), which will "spread" the "8" until it reaches "0", but when i tried to trigger when a date is reached, =IF(C$3>=J$1,MIN(D$3-SUM($F$3:G3),8),0), it only shows 1 date with an "8" in it. I tried calculating end date using WORKDAYS(C$3,D$3/8) which is 1/15/2020, but couldn't figure out how to stop at end date. Is this possible? Examples of how data should look below.

 

[arthurbr]

Starting in F1 try :=IF($C3>=F$1,MIN($D3-SUM($E3:E3),8),0)
pull right and down

 

[juddaaaa]

Try this

=IFERROR(IF(AND(F$1>=$C3,DATEDIF($C3,F$1,"D")<$D3/8), 8, ""),"")

Book1
	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W
1			Date	30/12/2019	31/12/2019	01/01/2020	02/01/2020	03/01/2020	04/01/2020	05/01/2020	06/01/2020	07/01/2020	08/01/2020	09/01/2020	10/01/2020	11/01/2020	12/01/2020	13/01/2020	14/01/2020	15/01/2020	16/01/2020
2	Project Start	Hrs
3	03/01/2020	72						8	8	8	8	8	8	8	8	8
4	09/01/2020	32												8	8	8	8
5	06/01/2020	48									8	8	8	8	8	8
Sheet1

Cell Formulas
Range	Formula
F3:W5	F3	=IFERROR(IF(AND(F$1>=$C3,DATEDIF($C3,F$1,"D")<$D3/8), 8, ""),"")

 

[juddaaaa]

Just noticed you skip weekends in your dates. Try this instead

=IFERROR(IF(AND(F$1>=$C3,NETWORKDAYS($C3,F$1)<=$D3/8), 8, ""),"")

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1					Date	30/12/2019	31/12/2019	01/01/2020	02/01/2020	03/01/2020	06/01/2020	07/01/2020	08/01/2020	09/01/2020	10/01/2020	13/01/2020	14/01/2020	15/01/2020	16/01/2020
2			Project Start	Hrs
3			03/01/2020	72						8	8	8	8	8	8	8	8	8
4			09/01/2020	32										8	8	8	8
5			06/01/2020	48							8	8	8	8	8	8
6
7
Sheet1

Cell Formulas
Range	Formula
F3:S5	F3	=IFERROR(IF(AND(F$1>=$C3,NETWORKDAYS($C3,F$1)<=$D3/8), 8, ""),"")

 

[Dclem]

Juddaaa that worked....never would have thought of doing it that way! Thanks.

 

[juddaaaa]

You're very welcome.

Glad to help