Splitting Ranges of Data Apart

[ExcelNewbie0012]

Hello to all who might be able to assist me and my colleagues with this.

I am trying to find a way to split the ranges of numbers apart and to get each individual number that would be in that range. For instance, some of the data I am working with is:

120751.120754​

120760.120764​

100100.100150​

​

I would like some assistance on how to split it up so I would get a return on the next column of:

120751, 120752, 120753, 120754

102760, 120761, 120762, 120763, 120764

100100, 100101, 100102, etc etc

It's been a difficult one to tackle as some of the ranges can be generically wide, making up of up to 200 different amounts.

Any help would be greatly appreciated,
Thank you in advance

 

[hagia_sofia]

Hello, something along these lines?

=MAP(A1:A3,LAMBDA(x,
LET(
a,x,
start,--(TEXTBEFORE(a,".")),
end,--(TEXTAFTER(a,".")),
TEXTJOIN(", ",,start+SEQUENCE(,end-start+1,0)))))

 

[ExcelNewbie0012]

That worked incredibly well, you are amazing. Thank you so much. You're a life saver
Have a great day!

 

[JEC]

A variation

=LET(t,C1:C3,MAP(TEXTBEFORE(t,"."),TEXTAFTER(t,"."),LAMBDA(a,b,TEXTJOIN(",",,SEQUENCE(b-a+1,,a)))))

 

[JEC]

Or in seperate cells

=LET(t,C1:C3,a,TEXTBEFORE(t,"."),b,TEXTAFTER(t,"."),s,SEQUENCE(,MAX(b-a+1)),IF(s<=(b-a+1),a-1+s,""))

 

[ExcelNewbie0012]

Or in seperate cells

=LET(t,C1:C3,a,TEXTBEFORE(t,"."),b,TEXTAFTER(t,"."),s,SEQUENCE(,MAX(b-a+1)),IF(s<=(b-a+1),a-1+s,""))

Those 2 also work wonders! How people become so efficient in excel to that extent amazes me!

Thank you kindly!

 

[JEC]

You're welcome, cheers!