Split text string with characters

[max_max]

Hello to all,
How can I divide this string of texts:

minimo maggiore, via gallo 788 - san giovanni giovanni, 88018 / brindisi
or
minimo maggiore, via gallo 788, san giovanni giovanni, 88018, brindisi

in 5 colums without using function text in columns?
max_max

 

[Special-K99]

With the data in A1

in B1
=SUBSTITUTE(SUBSTITUTE(A1," -",",")," /",",")

in C1
=TRIM(MID(SUBSTITUTE($B1,",",REPT(" ",LEN($B1))),(COLUMNS($B1:B1)-1)*(LEN($B1))+1,LEN($B1)))
copy the formula in C1 across the row

Now copy ALL the formulas in row 1 down for as many rows of data you have

 

[max_max]

Hi special-k99,
it's o.k..
I added a new character :

minimo maggiore, via gallo 788 - san giovanni giovanni : 88018 / brindisi

I have updated this formula as follows:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2," -",",")," /",","),":",",")

it's right?
Up to how many SUBSTITUTES you can add to the formula?
Thank you so much.
Does the formula work on excel 2003?
max_max

 

[Special-K99]

You can add as many SUBSTITUTEs as you like

 

[max_max]

Hi special-k99
Thank you.
max_max

 

[Peter_SSs]

Up to how many SUBSTITUTES you can add to the formula?

Does the formula work on excel 2003?

You can add as many SUBSTITUTEs as you like

Actually there are limits

In more recent versions of Excel you can nest such functions for 64 levels (but hopefully you never actually do that!)

In Excel 2003, that you asked specifically about, you can only have 7 levels of nesting. That is, the original SUBSTITUTE() and 7 more around that.

 

[Special-K99]

Well, yes there are limits but I dont expect he will reach them, or if he does he could create a second cell with further SUBSITUTEs.
I dont have Excel 2003.