Speed up VBA Code (Hide Blank cells based on specific cell)

[CamC]

Hi there,

I have the following code that is working, but it is taking around 1 min to run. Is there anything I can do to improve the vba Speed?

What I am trying to do is automatically hiding blank rows (from B68 to B362) after Pasting in cell B27. This macro run for Sheet2 only (There is another different macro for Sheet1)

Private Sub Worksheet_Change(ByVal Target As Range)
    ' Show any hidden rows if this macro has been used
    Range("68:362").EntireRow.Hidden = False
    'Automate run macro if Past used in cell B27
        If Intersect(Target, Range("B27")) Is Nothing Then Exit Sub
        Application.ScreenUpdating = False
    'Hide rows if blank
        For Each cell In Range("B68:B362")
            If cell.Value2 = "" Then cell.EntireRow.Hidden = True
        Next cell
    Application.ScreenUpdating = True
End Sub

Much appreciated any help

 

[footoo]

If B27:B362 contains no formulas :

Private Sub Worksheet_Change(ByVal Target As Range)

'Automate run macro if B27 changed
If Intersect(Target, Range("B27")) Is Nothing Then Exit Sub

With Application
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False

' Hide all rows
Range("68:362").EntireRow.Hidden = True
'Unhide rows if not blank
Range("B68:B362").SpecialCells(xlCellTypeConstants).EntireRow.Hidden = False
    
    .Calculation = xlCalculationAutomatic
    .ScreenUpdating = True
    .EnableEvents = True
End With

End Sub

If B68:B362 contains formulas, post again.

 

[Peter_SSs]

@CamC
When posting vba code in the forum, please use the available code tags. It makes your code much easier to read/debug & copy. My signature block below has more details. I have added the tags for you this time.

 

[CamC]

If B27:B362 contains no formulas :

Private Sub Worksheet_Change(ByVal Target As Range)

'Automate run macro if B27 changed
If Intersect(Target, Range("B27")) Is Nothing Then Exit Sub

With Application
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False

' Hide all rows
Range("68:362").EntireRow.Hidden = True
'Unhide rows if not blank
Range("B68:B362").SpecialCells(xlCellTypeConstants).EntireRow.Hidden = False
   
    .Calculation = xlCalculationAutomatic
    .ScreenUpdating = True
    .EnableEvents = True
End With

End Sub

If B68:B362 contains formulas, post again.

Its worked perfect. Thank you so much footoo

 

[CamC]

@CamC
When posting vba code in the forum, please use the available code tags. It makes your code much easier to read/debug & copy. My signature block below has more details. I have added the tags for you this time.

Tks so much. Good to know