Sorting numbers accoring to chosen category

[KiraJensen]

I have created an excel sheet, where there are two buttons opening two different userforms; one for creating a new project, and one for updating project information.

Some of the informations in these userforms are as an example; ID numbers and project types.

The next step is creating a new userform where the different projects can be viewed on a list.

I therefore have to be able to sort between the different task types, in a userform with two ListBoxes.
1. In the first ListBox the user should be able to select the project type
2. The second ListBox should depend on the first ListBox, where the ListBox should only show the ID numbers which belongs to the chosen project type

The list of ID numbers and Project Types looks something like this:

ID Project Type
10001 Meeting
10002 Development
10003 Support
10004 Design
10005 Construction
10006 Development
10007 Development
10008 Support
10009 Meeting

ect....

Both ListBoxes should also be dynamic due to there constantly being created new project types and ID numbers



Any help would be much appriciated!

 

[Fluff]

Hi & welcome to MrExcel.
How about

Option Explicit
Private Dic As Object

Private Sub ListBox1_Click()
Me.ListBox2.Clear
Me.ListBox2.List = Dic(Me.ListBox1.Value).keys
End Sub

Private Sub UserForm_Initialize()
   Dim v1 As String, v2 As String
   Dim Cl As Range
   Set Dic = CreateObject("scripting.dictionary")
   Dic.CompareMode = vbTextCompare
   With Sheets("pcode")
      For Each Cl In .Range("B2", .Range("B" & Rows.Count).End(xlUp))
         v1 = Cl.Value: v2 = Cl.Offset(, -1).Value
         If Not Dic.exists(v1) Then
            Dic.Add v1, CreateObject("scripting.dictionary")
            Dic(v1).Add v2, Nothing
         ElseIf Not Dic(v1).exists(v2) Then
            Dic(v1).Add v2, Nothing
         End If
      Next Cl
   End With
   Me.ListBox1.List = Dic.keys
End Sub