Sorted array of unique items and their values with filter and sumifs

[Alizba]

I am currently working on an excel formula which give me a sorted array of unique items and their values.
I have reconciled the steps in the following excel but couldnt crack it to one step.
The difficulty is also higher due to the multiplication of two colomns (i.e. asset value & % ownership).
The goal is: How to get unique Asset Name for one owner sorted by ownership value (Asset Value * % ownership).
Thank you for your suggestions.

Excel problem.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1	Asset Name	Asset Value ($)	% ownership	Owner
2	A	36	70%	Ali
3	B	71	80%	Bali		Step I	compute ownership value
4	A	67	90%	Ali
5	B	380	100%	Ali		Ali
6	C	62	60%	Cali		Asset name	Ownership (in $)
7	C	13	50%	Bali		A	25.2	=(FILTER(B2:B8,D2:D8=$F$5))*(FILTER(C2:C8,D2:D8=$F$5))
8	C	67	60%	Cali		A	60.3	=(FILTER(A2:A8,D2:D8=$F$5))
9						B	380
10
11
12						Step II	Get unique asset owned by Ali
13
14						Unique Asset name
15						A		=UNIQUE((FILTER(A2:A8,D2:D8=$F$5)))
16						B
17
18						Step III - Use sumifs and sort & Sort by --> FINAL
19
20						Unique Asset name for Ali
21						B	380	=SORT(SUMIFS(G7#,F7#,UNIQUE((FILTER(A2:A8,D2:D8=$F$5)))),,-1)
22						A	85.5	=SORTBY(UNIQUE((FILTER(A2:A8,D2:D8=$F$5))),SUMIFS(G7#,F7#,UNIQUE((FILTER(A2:A8,D2:D8=$F$5)))),-1)
Sheet1

Cell Formulas
Range	Formula
F7:F9	F7	=(FILTER(A2:A8,D2:D8=$F$5))
G7:G9	G7	=(FILTER(B2:B8,D2:D8=$F$5))*(FILTER(C2:C8,D2:D8=$F$5))
H7,H21	H7	=FORMULATEXT(G7)
H8,H22	H8	=FORMULATEXT(F7)
F15:F16	F15	=UNIQUE((FILTER(A2:A8,D2:D8=$F$5)))
H15	H15	=FORMULATEXT(F15)
F21:F22	F21	=SORTBY(UNIQUE((FILTER(A2:A8,D2:D8=$F$5))),SUMIFS(G7#,F7#,UNIQUE((FILTER(A2:A8,D2:D8=$F$5)))),-1)
G21:G22	G21	=SORT(SUMIFS(G7#,F7#,UNIQUE((FILTER(A2:A8,D2:D8=$F$5)))),,-1)
Dynamic array formulas.

 

[Fluff]

How about

=LET(f,FILTER(A2:C8,D2:D8=F5),u,UNIQUE(INDEX(f,,1)),s,INDEX(f,,2)*INDEX(f,,3),SORT(CHOOSE({1,2},u,MMULT(--(TRANSPOSE(INDEX(f,,1))=u),s)),2,-1))