Sort Contents Of Cell

[Nanogirl21]

Is there a way to sort contents of a cell in alphabetical order? Each value that need to be sorted is seperated by , (comma space).

EXAMPLE IN COLUMN E:

RICE, CHEERIES, BANANAS, CUCUMBERS, BREAD

WANTED RESULTS IN COLUMN E:

BANANAS, BREAD, CHERRIES, CUCUMBERS, RICE

 

[Peter_SSs]

Test this in a copy of your workbook (as it over-writes the original column E values as requested)

Sub SortCellValues()
  Dim AL As Object
  Dim a As Variant, sWord As Variant
  Dim i As Long
  
  Set AL = CreateObject("System.Collections.ArrayList")
  a = Range("E1", Range("E" & Rows.Count).End(xlUp)).Value
  For i = 1 To UBound(a)
    AL.Clear
    For Each sWord In Split(a(i, 1), ", ")
      AL.Add sWord
    Next sWord
    AL.Sort
    a(i, 1) = Join(AL.ToArray, ", ")
  Next i
  Range("E1").Resize(UBound(a)).Value = a
End Sub

 

[Nanogirl21]

Test this in a copy of your workbook (as it over-writes the original column E values as requested)

Sub SortCellValues()
  Dim AL As Object
  Dim a As Variant, sWord As Variant
  Dim i As Long
  
  Set AL = CreateObject("System.Collections.ArrayList")
  a = Range("E1", Range("E" & Rows.Count).End(xlUp)).Value
  For i = 1 To UBound(a)
    AL.Clear
    For Each sWord In Split(a(i, 1), ", ")
      AL.Add sWord
    Next sWord
    AL.Sort
    a(i, 1) = Join(AL.ToArray, ", ")
  Next i
  Range("E1").Resize(UBound(a)).Value = a
End Sub

Worked perfect. Thank you.

 

[Peter_SSs]

Worked perfect. Thank you.

You're welcome.