Sort by Active Table, Help.

[teksp0rt]

Please help. I cannot get this macro to work.... I am trying to sort by the active table, criteria is column 1. Then I would like to add a second critera, column 5 of the table. I keep getting an error on the line...

".Sort.SortFields.Add Key:=Range([activeTable("Column1")]), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal"

HERE IS THE CODE:



Sub SortActiveTable()


Dim ws As Worksheet
Dim tbl As ListObject
Dim activeTable As String


Set ws = ActiveSheet
activeTable = ActiveCell.ListObject.Name


Set tbl = ws.ListObjects(activeTable)

With tbl
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=Range([activeTable("Column1")]), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.Apply
End With


End Sub

 

[Kamolga]

As you put " " around column1, I guess that is the name of the column (title) you want to sort with. Then this macro works

Sub SortActiveTable()

Dim ws As Worksheet
Dim tbl As ListObject
Dim activeTable As String

Set ws = ActiveSheet
activeTable = ActiveCell.ListObject.Name

Set tbl = ws.ListObjects(activeTable)
With tbl
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=Range(tbl & "[[#All],[Column1]]"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.Apply
End With

End Sub

If what you wish is to sort with the first column in position (whatever its name is) then this one would do the job

Sub SortActiveTable()

Dim ws As Worksheet
Dim tbl As ListObject
Dim activeTable As String

Set ws = ActiveSheet
activeTable = ActiveCell.ListObject.Name

Set tbl = ws.ListObjects(activeTable)

Dim Col1 As String
Col1 = ws.ListObjects(activeTable).ListColumns(1).Name

With tbl
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=Range(tbl & "[[#All],[" & Col1 & "]]"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.Apply
End With

End Sub

 

[John_w]

Please help. I cannot get this macro to work.... I am trying to sort by the active table, criteria is column 1. Then I would like to add a second critera, column 5 of the table.

    With tbl
        .Sort.SortFields.Clear
        .Sort.SortFields.Add Key:=.HeaderRowRange(, 1), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .Sort.SortFields.Add Key:=.HeaderRowRange(, 5), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .Sort.Apply
    End With

 

[teksp0rt]

Kamolga - Thank you. I used your second example. Thought was cleaner.

Sub SortActiveTable()


Dim ws As Worksheet
Dim tbl As ListObject
Dim activeTable As String
Dim Col1 As String
Dim Col5 As String


Set ws = ActiveSheet
activeTable = ActiveCell.ListObject.Name


Col1 = ws.ListObjects(activeTable).ListColumns(1).Name
Col5 = ws.ListObjects(activeTable).ListColumns(5).Name


Set tbl = ws.ListObjects(activeTable)

With tbl
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=Range(tbl & "[[#All],[" & Col1 & "]]"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.SortFields.Add Key:=Range(tbl & "[[#All],[" & Col5 & "]]"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.Apply
End With


End Sub

 

[Kamolga]

Glad it works