Solving For Implied Volatility using a UDF and Newton-Raphson

[K-MAN69]

Hi People,
I am struggling to code up a UDF that can be used to find out the implied volatility for a futures option given the following variables:

Option Price
Spot Price
Strike Price
Risk Free Rate (RFR)
Option Type ie Call or Put
Expiry Date
Deal Date

I have found the following code online but I cannot understand the Variables named "Seed" and I also don't understand "ctr" as I have highlighted below:

Function BlackScholesNewton(ByVal Seed As Double, ByVal
Precision As Double, ByVal S As Double, ByVal K As Double, ByVal r
As Double, ByVal q As Double, ByVal t As Double, ByVal sigma As
Double) As Double
Dim x_next As Double
Dim x_n As Double
Dim error_val As Double
Dim ctr As Integer
x_n = Seed
ctr = 0
Do
x_next = x_n - Black_Scholes(S, K, r, q, t, sigma) / Vega(S, K, r, q, t,
sigma)
error_val = x_next - x_n
x_n = x_next
ctr = ctr + 1
Loop Until (Abs(error_val) <= Precision Or ctr = 1000)
BlackScholesNewton = x_next​

End Function

Can anyone tell me what this means?

 

[craig.penny]

It looks like "Seed" is just used as the starting point for an iterative process. So long as the chosen seed isn't an outlier, the function should converge. The "ctr" variable is a counter that's counting how many iterations have occurred. The assumption in this UDF is that if it hasn't converged after 1000 iterations, it's not going to.

Full and open disclosure - my math isn't what it used to be so you ought to take this with a grain of salt.

 

[K-MAN69]

Thank you for that explaination it certainly makes sense from what I could guess as well - thanks again

 

[craig.penny]

Glad it makes sense!

 

[Simulationconsultant]

You might want to check out the implied volatility spreadsheet at http://investexcel.net/2118/implied-volatility-vba/.

It uses Newton-Raphson iteration coded in VBA

 

[K-MAN69]

Thanks so much that is a great website. Best code for Implied Volatility that I have seen so far.

 

[K-MAN69]

I created the code below that is much better than above

Option Explicit

Function OptionPriceBlack76(Expiry As Date, DealDate As Date, Spot As Double, Strike As Double, RFR As Double, Vol As Double, OptType As String)
Dim TimeYears As Double
Dim d1 As Double
Dim d2 As Double
Dim ert As Double
Dim N_Dash_d1 As Double 'The normal distribution curve
 
TimeYears = (Expiry - DealDate + 1) / 360
d1 = (Application.Ln(Spot / Strike) + Vol ^ 2 * TimeYears * 0.5) / (Vol * TimeYears ^ 0.5)
d2 = d1 - Vol * TimeYears ^ 0.5
ert = Exp(-RFR * TimeYears)
N_Dash_d1 = (1 / ((2 * 3.14159265358979) ^ 0.5)) * Exp((-d1 ^ 2) * 0.5)
 
'Price
If OptType = "C" Then
            OptionPriceBlack76 = ert * (Spot * Application.NormSDist(d1) - Strike * Application.NormSDist(d2))
ElseIf OptType = "P" Then
            OptionPriceBlack76 = ert * (Strike * Application.NormSDist(-d2) - Spot * Application.NormSDist(-d1))
End If
End Function

Function Vega_Black76(Expiry As Date, DealDate As Date, Spot As Double, Strike As Double, Vol As Double, RFR As Double, OptType As String) As Double
Dim TimeYears As Double
Dim d1 As Double
Dim d2 As Double
Dim ert As Double
Dim N_Dash_d1 As Double 'The normal distribution curve
 
TimeYears = (Expiry - DealDate + 1) / 360
d1 = (Application.Ln(Spot / Strike) + Vol ^ 2 * TimeYears * 0.5) / (Vol * TimeYears ^ 0.5)
d2 = d1 - Vol * TimeYears ^ 0.5
ert = Exp(-RFR * TimeYears)
N_Dash_d1 = (1 / ((2 * 3.14159265358979) ^ 0.5)) * Exp((-d1 ^ 2) * 0.5)
Vega_Black76 = Spot * ert * N_Dash_d1 * TimeYears ^ 0.5
End Function

Function AA_ImpliedVol_FutOpt(Expiry As Date, DealDate As Date, Spot As Double, Strike As Double, OptPrice As Double, RFR As Double, OptType As String)
Dim Vol As Double 'This is our first guess for Vol
Dim Accuracy As Double 'How accurate you want the calc to be
Dim i As Integer 'This is the iteration counter
Dim MaxIter As Integer 'This is the maximum allowable iterations the calc will do
Dim Value_1 As Double
Dim Vega_1 As Double
Dim NRF As Double '(OptPrice [Using Guess] - Observed OptPrice)/Vega [Using Guess]
Vol = 0.1
Accuracy = 0.00000000001
MaxIter = 100
i = 1
Do
   Value_1 = OptionPriceBlack76(Expiry, DealDate, Spot, Strike, RFR, Vol, OptType)
   Vega_1 = Vega_Black76(Expiry, DealDate, Spot, Strike, Vol, RFR, OptType)
   NRF = (Value_1 - OptPrice) / Vega_1
   Vol = Vol - NRF
   i = i + 1
   
Debug.Print "Value_1: " & Value_1
Debug.Print "Vega_1: " & Vega_1
Debug.Print "NRF: " & NRF
Debug.Print "Vol: " & Vol
Debug.Print "Iteration: " & i
    
Loop Until Abs(NRF) <= Accuracy Or i = MaxIter
AA_ImpliedVol_FutOpt = Vol
 
End Function
[CODE/]