Snapshot as a popup

[AngleseyExcel]

Option Explicit
Sub Rng_Snapshot()
 Dim rng As Range
 
 Application.ScreenUpdating = False
 
 Set rng = Sheet89.Range("U14:AU61")
 
 rng.CopyPicture
 
 On Error Resume Next
 
 Sheet4.Range("A1").PasteSpecial
 
 Set rng = Nothing
 
 Application.ScreenUpdating = True
 End Sub

I'm using the above code to create a snapshot of a range of data and post the snapshot into a seperate sheet. Is there any way if modifying it so it displays the snapshot as a popup window ?

Any help would be greatly appreciated. TIA

 

[NdNoviceHlp]

Hi AngelseyExcel and Welcome to this Board. The problem is that the range is really large. You can make a popup window sort of by adding a userform and placing a large frame control on it. You will need to add the following code....
Module code...

Public TempA As Double
Public TempB As Double
Public Sub createJpg(SheetName As String, xRgAddrss As Range, nameFile As String)
Dim xRgPic As Range
Application.ScreenUpdating = False
Worksheets(SheetName).Activate
Set xRgPic = xRgAddrss
xRgPic.CopyPicture
TempA = xRgPic.Width
TempB = xRgPic.Height
With ThisWorkbook.Worksheets(SheetName).ChartObjects.Add(xRgPic.Left, xRgPic.Top, xRgPic.Width, xRgPic.Height)
.Activate
.Chart.Paste
.Chart.Export Environ$("temp") & "" & nameFile & ".jpg", "JPG"
End With
Worksheets(SheetName).ChartObjects(Worksheets(SheetName).ChartObjects.Count).Delete
Application.ScreenUpdating = True
End Sub

Userform code...

Private Sub UserForm_Initialize()
With UserForm1.Frame1
.BorderStyle = fmBorderStyleNone
.Caption = vbNullString
.ScrollBars = fmScrollBarsBoth
.ScrollHeight = TempB
.ScrollWidth = TempA
.Picture = LoadPicture(Environ$("temp") & "" & "TempChart.jpg")
.PictureSizeMode = fmPictureSizeModeClip
End With
Kill (Environ$("temp") & "" & "TempChart.jpg")
End Sub

To operate with your range run this Test sub....

Sub test()
Call createJpg("Sheet89", ThisWorkbook.Worksheets("Sheet89").Range("U14:AU61"), "TempChart")
UserForm1.Show
End Sub

HTH. Dave

 

[AngleseyExcel]

Sub test() Call createJpg("Sheet89", ThisWorkbook.Worksheets("Sheet89").Range("U14:AU61"), "TempChart") UserForm1.Show End Sub

Hi Thanks for this, but this is specific to a certain sheet(Sheet89), how would i make it for the Active sheet that it's embedded on ?

 

[NdNoviceHlp]

This was your requested range posted...

Set rng = Sheet89.Range("U14:AU61")

You can adjust this part of the code (sheet name and/or range) to whatever....

Call createJpg("Sheet89", ThisWorkbook.Worksheets("Sheet89").Range("U14:AU61"), "TempChart")

I'm not sure what's "embedded" here, but to use the active sheet you need to change this....

Sub test()
Dim SheetName As String
SheetName = ActiveSheet.Name
Call createJpg(SheetName, ThisWorkbook.Worksheets(SheetName).Range("A1:U69"), "TempChart")
UserForm1.Show
End Sub

Please, in the future, be clear on what your desired outcome is. Dave

 

[AngleseyExcel]

This was your requested range posted...

Set rng = Sheet89.Range("U14:AU61")

You can adjust this part of the code (sheet name and/or range) to whatever....

Call createJpg("Sheet89", ThisWorkbook.Worksheets("Sheet89").Range("U14:AU61"), "TempChart")

I'm not sure what's "embedded" here, but to use the active sheet you need to change this....

Sub test()
Dim SheetName As String
SheetName = ActiveSheet.Name
Call createJpg(SheetName, ThisWorkbook.Worksheets(SheetName).Range("A1:U69"), "TempChart")
UserForm1.Show
End Sub

Please, in the future, be clear on what your desired outcome is. Dave

Thank you so much for your help.

 

[NdNoviceHlp]

You are Welcome. Thanks for posting your outcome. Be safe. Dave