Small change in coding

[harshab6]

Hi Experts,

I use below code to consolidate the data from different worksheet into single worksheet.Every time I run the macro it will create a sheet name consol_Tracking then it will consolidate data from different sheet to consol tracking main sheet.now I want the macro to avoid creating Consol tracking sheet a since it will be duplication because previously we use to delete previous consol tracking before Running the macro but now we thought of retaining it.I have tried several changes in coding I know there is small change to be made But unable ro sort it out.
Now my requirement is the Consol track sheet will be already available the macro has to consolidate the data from different sheet to single consol track sheet and other part of coding should run as it is.please find the below code.

Sub CopyFromWorksheets()[/COLOR][/FONT][COLOR=#000000]
    Dim wrk As Workbook 'Workbook object - Always good to work with object variables
    Dim sht As Worksheet 'Object for handling worksheets in loop
    Dim trg As Worksheet 'Consol_Tracking Worksheet
    Dim rng As Range 'Range object
    Dim colCount As Integer 'Column count in tables in the worksheets
    Set wrk = ActiveWorkbook 'Working in active workbook
    
    For Each sht In wrk.Worksheets
        If sht.Name = "Consol_Tracking" Then
            MsgBox "There is a worksheet called as 'Consol_Tracking'." & vbCrLf & _
            "Please remove or rename this worksheet since 'Consol_Tracking' would be" & _
            "the name of the result worksheet of this process.", vbOKOnly + vbExclamation, "Error"
            Exit Sub
        End If
        Next sht
    
     'We don't want screen updating
    Application.ScreenUpdating = False
    
     'Add new worksheet as the last worksheet
     Set trg = wrk.Worksheets.Add(After:=wrk.Worksheets(wrk.Worksheets.Count))
     'Rename the new worksheet
    trg.Name = "Consol_Tracking"
     'Get column headers from the first worksheet
     'Column count first
    Set sht = wrk.Worksheets(1)
    colCount = sht.Cells(1, 255).End(xlToLeft).Column
     'Now retrieve headers, no copy&paste needed
    With trg.Cells(1, 1).Resize(1, colCount)
        .Value = sht.Cells(1, 1).Resize(1, colCount).Value
         'Set font as bold
        .Font.Bold = True
    End With
    
     'We can start loop
    For Each sht In wrk.Worksheets
    'If worksheet in loop is the last one, stop execution (it is Consol_Tracking worksheet)
        If sht.Index = wrk.Worksheets.Count Then
            Exit For
        End If
         'Data range in worksheet - starts from second row as first rows are the header rows in all worksheets
                 Set rng = sht.Range(sht.Cells(2, 1), sht.Cells(65536, 1).End(xlUp).Resize(, colCount))
         'Put data into the Consol_Tracking worksheet
        trg.Cells(65536, 1).End(xlUp).Offset(1).Resize(rng.Rows.Count, rng.Columns.Count).Value = rng.Value
        Next sht
     'Fit the columns in Consol_Tracking worksheet
    trg.Columns.AutoFit
    
     'Screen updating should be activated
    Application.ScreenUpdating = True
End Sub[/COLOR][FONT=Calibri][COLOR=#000000]
[/COLOR][/FONT]

 

[Fluff]

Try

Sub CopyFromWorksheets()
   Dim wrk As Workbook 'Workbook object - Always good to work with object variables
   Dim sht As Worksheet 'Object for handling worksheets in loop
   Dim trg As Worksheet 'Consol_Tracking Worksheet
   Dim rng As Range 'Range object
   Dim colCount As Integer 'Column count in tables in the worksheets
   Set wrk = ActiveWorkbook 'Working in active workbook
   Set trg = wrk.Sheets("Consol_Tracking")
   
   'We don't want screen updating
   Application.ScreenUpdating = False
   
   'We can start loop
   For Each sht In wrk.Worksheets
      'If worksheet in loop is the last one, stop execution (it is Consol_Tracking worksheet)
      If sht.Name <> trg.Name Then
         'Data range in worksheet - starts from second row as first rows are the header rows in all worksheets
         Set rng = sht.Range(sht.Cells(2, 1), sht.Cells(65536, 1).End(xlUp).Resize(, colCount))
         'Put data into the Consol_Tracking worksheet
         trg.Cells(65536, 1).End(xlUp).Offset(1).Resize(rng.Rows.Count, rng.Columns.Count).Value = rng.Value
      End If
   Next sht
   'Fit the columns in Consol_Tracking worksheet
   trg.Columns.AutoFit
   
   'Screen updating should be activated
   Application.ScreenUpdating = True
End Sub

 

[harshab6]

Thanks for quick reply,I am getting Run time error 1004 in below code.

Set rng = sht.Range(sht.Cells(2, 1), sht.Cells(65536, 1).End(xlUp).Resize(, colCount))

 

[Fluff]

Add this line back in as shown

[COLOR=#ff0000] colCount = sht.Cells(1, 255).End(xlToLeft).Column[/COLOR]
Set rng = sht.Range(sht.Cells(2, 1), sht.Cells(65536, 1).End(xlUp).Resize(, colCount))

 

[harshab6]

Awesome.Thanks for help.

 

[Fluff]

You're welcome & thanks for the feedback