Slow VBA - Need Help Speeding it Up

[Bkisley]

Below is my current code. It works exactly as I need after a ton of different changes I have made. The issue is...the code takes like 30 seconds to run. It is not a dealbreaker however it is not very efficient. Any ideas on how I can speed this up??

Sub CreateInvoice()
    Range("A11:u500").Select
    Selection.Copy
    Range("B12").Select
    Selection.End(xlDown).Select
    Sheets("Invoice").Select
    Range("z9").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    
    Rows("10:514").EntireRow.AutoFit

Dim c As Range

    For Each c In Range("A10:A510").Cells
        If c.Value = "True" Then
            c.EntireRow.Hidden = True

        End If
    Next c
    
    Range("AA1:AL1").Select
    Selection.Copy
    Sheets("Invoice History").Select
    Range("B4").Select
    Selection.End(xlDown).Select
    Selection.End(xlDown).Select
    ActiveCell.Offset(1, 0).Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

    Sheets("Invoice").Select
    
    Range("B2:D6").Select
    
End Sub

 

[jasonb75]

Using Select and Selection is a good way to slow things down, as such, removing them will speed it up.

I've tried to keep this in line with what your code looks like it is doing but it is untested.

Sub CreateInvoice()
With Application
    .EnableEvents = False
    .ScreenUpdating = False
    .Calculation = xlManual
End With
    Range("A11:U500").Copy
With Sheets("Invoice")
    .Range("z9").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
    :=False, Transpose:=False
    .Rows("10:514").EntireRow.AutoFit

        Dim c As Range
    For Each c In .Range("A10:A510").Cells
        If c.Value = "True" Then
            c.EntireRow.Hidden = True
        End If
    Next c
    .Range("AA1:AL1").Copy
End With
With Sheets("Invoice History")
    .Range("B4").End(xlDown).End(xlDown).Offset(1, 0).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
End With
With Application
    .EnableEvents = True
    .ScreenUpdating = True
    .Calculation = xlAutomatic
End With
    
End Sub