Skip cell based on another cell

[Ingko]

Hi all,
Appreciate the assist with a weird one I have.

I dump some report data into multiple tabs and have Tab1 as an overall summary but stumped on an efficient way to skip/insert blank cells based on a reference to another tab. I'll attempt to describe my problem with a Tab-Cell reference format below:

Tab1-A1 is filled by reference to Tab2-A1 (lets say some sort of requisition ID# like "REQ111". [Therefore the result in Tab1 cell A1 = Tab2 cell A1 i.e. "REQ111"]
Tab1-A2 is filled by reference to Tab2-A2 REQ222
Tab1-A3 is filled by reference to Tab2-A3 REQ333
However...
Tab1-A4 is filled by reference to Tab2-A4 SUP111
Tab1-A5 is supposed to be filled by reference to Tab2-A5 but because the previous ID# begins with something other than "REQ" I want to leave Tab1-A5 BLANK
Then as a continuation...
Tab1-A6 is filled by reference to Tab2-A5 REQ444 <= In Tab2, the data dump doesn't have any breaks or blanks. It's only in Tab1 where I want the blank cell, once a blank cell is inserted I need it to continue from Tab2 where it left off.

If Tab2 had 1000 rows of data, of which 56 of those begin with something other than "REQ" then in Tab1 I'd have a grand total of 1056 rows where 56 are blank.
I plan to fill in this blanks by some other conditional formula which I'll tag on later but I'm stuck on the insert blank but continue piece.
Can't/don't want to VBA or powerQuery as those are beyond scope of the staff who will use this file later on.

Thanks in advanced.

Cheers.

 

[Snakehips]

@Ingko Are you able to employ a 'helper' column in Tab2, which could be hidden if you wish?

Bridal Stuff2.xlsx
	A	B	C
1	REQ111		1
2	REQ222		2
3	REQ333		3
4	SUP111		3
5	REQ444		4
6	REQ555		5
7	SUP222		5
8	REQ666		6
9			6
10			6
Tab2

Cell Formulas
Range	Formula
C1:C10	C1	=COUNTIF(A$1:A1,"REQ*")

Bridal Stuff2.xlsx
	A
1	REQ111
2	REQ222
3	REQ333
4	REQ444
5	REQ555
6	REQ666
7
Tab1

Cell Formulas
Range	Formula
A1:A7	A1	=IFERROR(INDEX('Tab2'!A$1:A$1000,MATCH(ROWS(A$1:A1),'Tab2'!C$1:C$1000,0)),"")

I am working with Excel 2010 so do not know if there are better solutions using some of the newer features within 356.
Hope that helps.

 

[Snakehips]

Or you could have the 'helper' column in Tab1

Bridal Stuff2.xlsx
	A	B	C	D	E	F
1	REQ111				1
2	REQ222				2
3	REQ333				3
4	REQ444				3
5	REQ555				4
6	REQ666				5
7					5
8					6
9					6
10					6
Tab1

Cell Formulas
Range	Formula
A1:A10	A1	=IFERROR(INDEX('Tab2'!A$1:A$1000,MATCH(ROWS(A$1:A1),E$1:E$1000,0)),"")
E1:E10	E1	=COUNTIF('Tab2'!A$1:A1,"REQ*")

 

[Fluff]

My take on this

+Fluff 1.xlsm
	A
1	REQ111
2	REQ222
3	REQ333
4	SUP111
5	REQ444
6	REQ555
7	SUP222
8	REQ666
9
Sheet2

+Fluff 1.xlsm
	A
1	REQ111
2	REQ222
3	REQ333
4	SUP111
5
6	REQ444
7	REQ555
8	SUP222
9
10	REQ666
11
12
Sheet1

Cell Formulas
Range	Formula
A1	A1	=Sheet2!A1
A2:A12	A2	=IFERROR(INDEX(Sheet2!$A$1:$A$8,IF(OR(LEFT(A1,3)="req",A1=""),ROW()-COUNTIFS(A$1:A1,""),"")),"")

 

[Snakehips]

^^^^Looks like I need to learn to read properly!

 

[Ingko]

Thanks @Fluff and @Snakehips , Solution found

 

[Fluff]

Glad we could help & thanks for the feedback.