Simplify the code, write everything in less than 20 lines

[Ossian13]

Hi Everyone,

i was wondering if this code

Range("A1").EntireRow.Copy
Sheets.Add After:=ActiveSheet
ActiveSheet.Name = "Pending"
ActiveSheet.Paste
Cells.EntireColumn.AutoFit
Sheets.Add After:=ActiveSheet
ActiveSheet.Name = "Closed"
Worksheets("Sursa").Select
Rows("1:1").Select
Application.CutCopyMode = False
Selection.Copy
Worksheets("Closed").Activate
Range("A1").Select
ActiveSheet.Paste
Cells.EntireColumn.AutoFit
Worksheets("Closed").Select
Rows("1:1").Select
Application.CutCopyMode = False
Selection.Copy
Sheets.Add After:=ActiveSheet
ActiveSheet.Name = "Approved"
ActiveSheet.Paste
Cells.EntireColumn.AutoFit
Rows("1:1").Select
Application.CutCopyMode = False
Selection.Copy
Sheets.Add After:=ActiveSheet
ActiveSheet.Name = "Sursa2"
ActiveSheet.Paste
Cells.EntireColumn.AutoFit
Worksheets("Sursa").Select

could be simplified in fewer lines. It adds some sheets, copies the first row, paste the same row on all the sheets and autofits the size.

Thank you,
Ossian.

 

[mole999]

something like this from the macro recorder and tweaked

Sub Macro1()

    Sheets.Add.Name = "Pending"
    Sheets.Add.Name = "Closed"
    Sheets.Add.Name = "Approved"
    Sheets.Add.Name = "Sursa2"
    
    Sheets("Sheet1").Select
    Rows("1:1").Select
    Selection.Copy
    
    Sheets(Array("Pending", "Closed", "Approved", "Sursa2")).Select
    Rows("1:1").Select
    ActiveSheet.Paste
    
    Sheets("Sheet1").Select

End Sub

as an example

 

[MARK858]

Just another method..

Sub CopyToAllSheets()
    Dim shArray(), i As Long, mysht As String
    mysht = ActiveSheet.Name

    shArray = Array(mysht, "Pending", "Closed", "Approved", "Sursa2")

    For i = LBound(shArray) + 1 To UBound(shArray)
        Sheets.Add().Name = shArray(i)
    Next i
    
    Sheets(shArray).FillAcrossSheets Sheets(mysht).Rows(1)
    
    For i = LBound(shArray) + 1 To UBound(shArray)
        Sheets(shArray(i)).Columns.AutoFit
    Next i
End Sub

 

[Ossian13]

Thank you both! and sorry for the late reply! Much appreciated!