Simplest VBA for Row Deletion in a given worksheet if Column A = FALSE

[cubewarrior]

Greetings,

I have manage to create the appropriate merging of my data to a single worksheet, and created Column A to validate the row and tell me if "True", then I need the row or "False", I can delete the row.

Is there simple VBA code that can check a given worksheet and delete any row where Column A = False? I am thinking of this as a button macro another worksheet I can activate to perform this action. I have poured over the forums here and did not find this exactly. I am hoping it is simple.

I am on a PC with Excel 2013.

Thank you !

-CW

 

[heifer624]

Sub DeleteFalse()
With ActiveSheet
    .AutoFilterMode = False
    With Range("A2", Range("A" & Rows.Count).End(xlUp))
        .AutoFilter 1, "False"
        On Error Resume Next
        .Offset(1).SpecialCells(12).EntireRow.Delete
    End With
    .AutoFilterMode = False
End With
End Sub

 

[Michael M]

Maybe this for the active sheet.
Paste the code into a Standard Module

Option Compare Text
Sub MM1()
Dim lr As Long, r As Long
Application.ScreenUpdating = False
lr = Cells(Rows.Count, "A").End(xlUp).Row
For r = lr To 1 Step -1
    If Range("A" & r).Value = "False" Then
        Rows(r).Delete
    End If
Next r
Application.ScreenUpdating = True
End Sub

 

[cubewarrior]

Heifer and Michael - Thank you both - both sets of code works great. Much appreciative of the help

-CW

 

[Michael M]

Glad to help...you'll find if you have a larger data set, that heifer624s code will be more efficient !!.....