Simple Fill Down Problem...

[JWooz]

How do I fill down keeping the same row number pattern? How to keep this pattern going:
=Sheet1!A1
=Sheet1!B1
=Sheet1!A2
=Sheet1!B2
=Sheet1!A3
=Sheet1!B3

As always, any help is appreciated.

JWooz

 

[offthelip]

try this:

=OFFSET(Sheet1!$A$1,(INT(((ROW()-1)/2))),MOD(ROW()-1,2))

 

[JWooz]

try this:

=OFFSET(Sheet1!$A$1,(INT(((ROW()-1)/2))),MOD(ROW()-1,2))

Thank you!

 

[JWooz]

Hey... just for my own education... how would you do it if you wanted to do the same thing with multiple columns? For example:
A1 B1 C1 D1
E1 F1 G1 H1

??

 

[BigBeachBananas]

If you have Excel D365, you can use =WRAPCOLS()

=WRAPROWS(A1:H1,4)

 

[Peter_SSs]

I suggest that you update your Account details (or click your user name at the top right of the forum) so helpers always know what Excel version(s) & platform(s) you are using as the best solution often varies by version. (Don’t forget to scroll down & ‘Save’)

For the original question here are a couple of options (depending on your version) that avoid the use of the volatile function OFFSET

23 10 10.xlsm
	A	B
1	a	b
2	c	d
3	e	f
4	g	h
Sheet1

23 10 10.xlsm
	A	B
1	a	a
2	b	b
3	c	c
4	d	d
5	e	e
6	f	f
7	g	g
8	h	h
JWooz

Cell Formulas
Range	Formula
A1:A8	A1	=INDEX(Sheet1!A:B,(ROWS(A$1:A1)+1)/2,1+ISEVEN(ROWS(A$1:A1)))
B1:B8	B1	=INDEX(TOCOL(Sheet1!A$1:B$4),ROWS(B$1:B1))

 

[JWooz]

Thanks. Account details updated.

 

[JWooz]

Thanks BigBeachBananas... I went with yours and it works perfect. I changed the expression to:

=WRAPROWS('Paste Report Here'!A1:'Paste Report Here'!N1,7)

 

[JWooz]

If you have Excel D365, you can use =WRAPCOLS()

=WRAPROWS(A1:H1,4)

Ok... I posted too soon. Still skips the next row. No matter what I do, as I fill down it skips. I get this:
In cell A1 I have

=WRAPROWS('Paste Report Here'!A1:'Paste Report Here'!N1,7)

But when I fill down I get the following

=WRAPROWS('Paste Report Here'!A3:'Paste Report Here'!N3,7)

- it skips Row 2 and continues on.

Trying to make myself clear here as perhaps I haven't previously (me and not you all)... I want for printing purposes, to be able to have the following:
Row 1 - A1 B1 C1 D1 E1 F1 G1
Row 2 - H1 I1 J1 K1 L1 M1 N1
Row 3 - A2 B2 C2 D2 E2 F2 G2
Row 4 - H2 I2 J2 K2 L2 M2 N2
Row 5 - A3 B3 C3 D3 E3 F3 G3
Row 6 - H3 I3 J3 K3 L3 M3 N3
And so on...

As always, your time and help is very much appreciated.

JWooz

 

[BigBeachBananas]

It's a dynamic array so you don't want to fill it down. Instead, try

=WRAPROWS(TOCOL(A1:N3),7)