Set Array Name in a Cell and Reference in Code

[vandango05]

Good day all.

I'm using the code below to be able to create a pdf from multiple worksheets with different print areas as one file. The issue I have is that the array which determines which sheets to print as well as the print areas are different each time. It will be fairly easy for me to create a formula to create the array and print areas in a worksheet called "Summary" (Sheet32) in say cells A1 for the Array and A2 for the print area.

Is there a way i can reference the values in these cells in the code?

Sub printmultiplesheets()
    Dim path As String
    Dim myArr As Variant, a As Variant
    Dim rngArr As Variant
    Dim Ws As Worksheet
    Dim i As Integer
    


    myArr = Array("Contract 1st Page", "Windows", "Doors") '<~~ Sheet names
    
    rngArr = Array("C1:K57", "B2:BX95", "B2:BX111") '<~~ print area addresses


    For i = 0 To UBound(myArr)
        Set Ws = Sheets(myArr(i))
        With Ws
            .PageSetup.PrintArea = .Range(rngArr(i)).Address
        End With
    Next
    Sheets(myArr).Select


    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:=Sheet32.Range("S18").Value _
    , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
    :=False, OpenAfterPublish:=True




End Sub

 

[Norie]

What exactly will be in A1 and A2?

 

[Trebor76]

Here a possible method - just put the sheet names and their ranges as plain text separated by a comma i.e. don't use double quotes when entering them into cell A1 or A2 (refer my comments in the following code as well):

Option Explicit
Sub Macro1()

    Dim strSheetArray() As String
    Dim strRangeArray() As String
    Dim intArrayIndex As Integer
    Dim Ws As Worksheet
    
    Application.ScreenUpdating = False
    
    strSheetArray() = Split(Sheet32.Range("A1"), ",") '<~~ Sheet names like so: Contract 1st Page, Windows, Doors
    strRangeArray() = Split(Sheet32.Range("A2"), ",") '<~~ print area addresses like so: C1:K57, B2:BX95, B2:BX111
    
    For intArrayIndex = LBound(strSheetArray) To UBound(strSheetArray)
        Set Ws = ThisWorkbook.Sheets(strSheetArray(intArrayIndex))
        With Ws
            .PageSetup.PrintArea = .Range(strRangeArray(intArrayIndex)).Address
            .ExportAsFixedFormat Type:=xlTypePDF, Filename:=Sheet32.Range("S18").Value, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
        End With
    Next intArrayIndex
    
    Application.ScreenUpdating = True

End Sub

Regards,

Robert

 

[vandango05]

What exactly will be in A1 and A2?

It will identify which sheets to print and the print areas, it can be displayed in any way that would be suitable for example:

A1 - Contract 1st Page, Windows, Doors or Sheet5, Sheet6, Sheet7 or "Contract First Page", "Windows", "Doors"

A2 C1:K57, B2:BX95, B2:BX111 or "C1:K57", "B2:BX95", "B2:BX111"

or if it needs to be displayed a different way I can do this.

 

[vandango05]

Thanks for the replies. Code is stopping at Set Ws = ThisWorkbook.Sheets(strSheetArray(intArrayIndex))

In A1 i've got this Contract 1st Page, Windows, Doors and in A2 this C1:K57, B2:BX95, B2:BX111

Despite it not running it was still generating a PDF with just the "Contract 1st Page" Worksheet

 

[Norie]

I think you'll need to be careful with trailing/leading spaces if you are going to use a delimited list in a cell.

For example, from your list the second sheet name looks more like ' Windows' rather than 'Windows' and if you don't have a sheet named ' Windows' then you'll get a subscript out of range error on the line you've indicated.

 

[vandango05]

Thank you for your help so far. That indeed was the issue however its not quite working how I need it to. The original code created an array which then selected all worksheets within the array before saving them as PDF so it would be one file. The changed code will create separate PDF's for each worksheet.

 

[Trebor76]

Try this:

Option Explicit
Sub Macro2()

    Dim strSheetArray() As String
    Dim strRangeArray() As String
    Dim strSheetsArray() As String
    Dim intArrayIndex As Integer
    Dim Ws As Worksheet
    
    Application.ScreenUpdating = False
    
    strSheetArray() = Split(Sheet32.Range("A1"), ",") '<~~ Sheet names like so: Contract 1st Page, Windows, Doors
    strRangeArray() = Split(Sheet32.Range("A2"), ",") '<~~ print area addresses like so: C1:K57, B2:BX95, B2:BX111
    
    For intArrayIndex = LBound(strSheetArray) To UBound(strSheetArray)
        Set Ws = ThisWorkbook.Sheets(Trim(strSheetArray(intArrayIndex)))
        Ws.PageSetup.PrintArea = Range(Trim(strRangeArray(intArrayIndex))).Address
        ReDim Preserve strSheetsArray(0 To intArrayIndex)
        strSheetsArray(intArrayIndex) = Trim(strSheetArray(intArrayIndex))
    Next intArrayIndex
    
    Sheets(strSheetsArray).ExportAsFixedFormat Type:=xlTypePDF, Filename:=Sheet32.Range("S18").Value, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
    
    Application.ScreenUpdating = True

End Sub

 

[vandango05]

Hi Trebor76

Thank you for your help, initially had some issues but this appears to be down to my list created.

I also had to change the print at the end but now works perfectly. Thanks again.

Sub Macro2()

    Dim strSheetArray() As String
    Dim strRangeArray() As String
    Dim strSheetsArray() As String
    Dim intArrayIndex As Integer
    Dim Ws As Worksheet
    
    Application.ScreenUpdating = False
    
    strSheetArray() = Split(Sheet32.Range("S23"), ",") '<~~ Sheet names like so: Contract 1st Page, Windows, Doors
    strRangeArray() = Split(Sheet32.Range("S24"), ",") '<~~ print area addresses like so: C1:K57, B2:BX95, B2:BX111
    
    For intArrayIndex = LBound(strSheetArray) To UBound(strSheetArray)
        Set Ws = ThisWorkbook.Sheets(Trim(strSheetArray(intArrayIndex)))
        Ws.PageSetup.PrintArea = Range(Trim(strRangeArray(intArrayIndex))).Address
        ReDim Preserve strSheetsArray(0 To intArrayIndex)
        strSheetsArray(intArrayIndex) = Trim(strSheetArray(intArrayIndex))
    Next intArrayIndex
    
    Sheets(strSheetsArray).Select
    
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:=Sheet32.Range("S18").Value, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
    
    Application.ScreenUpdating = True


End Sub

 

[Trebor76]

You're welcome. I'm glad we got it resolved for you