Sending outlooks email from VBA

[RCOLIN]

Hi All - I piggy backed off a coworkers code to send an email from excel out of outlook. I would like to add a body to this email, with the cell range pasted below it.
s someone able to assist?
The body needs to say:

"53R – manager approved – branch responsibility

Muni ops –

Trading is copied on the email and approves.

Thank you in advance."

Sub Send53r()

Dim rng As Range
Set rng = Sheets("Sheet").Range("A1:S3")

With Application
.EnableEvents = False
.ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
' Set OutMail = OutApp.CreateItemFromTemplate(
' "C:\Users\zkajlkq\AppData\Roaming\Microsoft\Templates\BofAS Blue Banner.oft")
With OutMail
.To = email address removed for privacy
.CC = email address removed for privacy
.Subject = "53R"
.body = "53R - manager approved - branch responsibility "
.HTMLBody = RangetoHTML(rng)

.Display

End With

With Application
.EnableEvents = True
.ScreenUpdating = True

End With
Set OutMail = Nothing
Set OutApp = Nothing


End Sub

Function RangetoHTML(rng As Range)

Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook

TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With

' Publish the sheet to an .htm file.
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With


'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.ReadAll
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center xublishsource=", _
"align=left xublishsource=")

'Close TempWB
TempWB.Close savechanges:=False

'Delete the htm file we used in this function
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function

 

[Sequoyah]

Hi RCOLIN,
try this, I changed the function slightly, so copy it entirely

Sub Send53rForum()

Dim OutApp As Object, OutMail As Object
Dim rng As Range
Dim strBody As String

Const LineBreak = "<br>"

Set rng = Sheets("Sheet1").Range("A1:S3") 'ADAPT as needed
strBody = "53R – manager approved – branch responsibility" & LineBreak & _
      "Muni ops –" & LineBreak & _
      "Trading is copied on the email and approves." & LineBreak & _
      "Thank you in advance."

With Application
.EnableEvents = False
.ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
' Set OutMail = OutApp.CreateItemFromTemplate(
' "C:\Users\zkajlkq\AppData\Roaming\Microsoft\Templates\BofAS Blue Banner.oft")
With OutMail
.To = "email address removed for privacy"
.CC = "email address removed for privacy"
.Subject = "53R"
'.body = "53R - manager approved - branch responsibility "
.HTMLBody = strBody & RangetoHTML(rng)

.Display

End With

With Application
.EnableEvents = True
.ScreenUpdating = True

End With
Set OutMail = Nothing
Set OutApp = Nothing

End Sub

Function RangetoHTML(rng As Range)

Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
Dim i As Integer

TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0

For i = 7 To 12
            With .UsedRange.Borders(i)
                .LineStyle = xlContinuous
                .ColorIndex = xlAutomatic
                .TintAndShade = 0
                .Weight = xlMedium
            End With
        Next i
End With

' Publish the sheet to an .htm file.
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With


'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.ReadAll
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")

'Close TempWB
TempWB.Close savechanges:=False

'Delete the htm file we used in this function
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function