Sending email from excel

[zugfrig]

HI

IVE USED THIS THAT SOMEBODY BUILT FOR ME FOR A WHILE... I CHANGED A FEW THINGS TODAY NOW WHEN I TRY AND SEND IT GET THIS ERROR

 

[bugmonsta]

have you copied in the rangetohtml in the module as it says on line 2 of your code, I know its an obvious question but I have to ask it?

All this code is from Ron De Bruin website - its worth comparing his code to yours.

The link above will take you to the site, below is a copy of the rangetohtml code, it does state on his webpage:

Important: Be aware that if you have set Excel to R1C1 reference style the code will not work.
You can add this line at the start of your macro to be sure it is set to xlA1 style
Application.ReferenceStyle = xlA1

I don't know if this has been set by a change your have done?

your error is stating that it cannot find this function, either its renamed or removed from your file?

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function