Selection change breaks Filter

[drag1c]

Im using this code to resize cell on click, to autofit text. Unfortunately, this code breaks filter and unfilitered data pops-up.
Does anyone have idea what could be done here so filter always remain the same until manually changed?

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Static iRow As Long

    Application.EnableEvents = True

    If Target.Row = 1 Then
    UsedRange.Rows.RowHeight = 12.75
    Exit Sub
    End If
 
    If Not Intersect(Target, Range("D:D")) Is Nothing Then
        If Target.Rows.Count > 1 Then Exit Sub
            If iRow > 0 Then
                Rows(iRow).RowHeight = 12.75
            End If
            iRow = Target.Row
            Target.EntireRow.AutoFit
            If Target.EntireRow.Height < 22 Then
                Rows(iRow).RowHeight = 24.75
            End If
    End If

    If Intersect(Target, Range("D:D")) Is Nothing Then
        If Target.Rows.Count > 1 Then Exit Sub
        If iRow > 0 Then
            UsedRange.Rows.RowHeight = 12.75
        End If
    End If

Application.EnableEvents = True
End Sub

 

[DanteAmor]

. Unfortunately, this code breaks filter and unfilitered data pops-up.

I tried to reproduce that issue but couldn't.

Try the following to see if it works for you:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  Static iRow As Long
  Application.EnableEvents = False
  
  If Target.Row = 1 Then
    UsedRange.SpecialCells(xlCellTypeVisible).Rows.RowHeight = 12.75
    Application.EnableEvents = True
    Exit Sub
  End If
  If Target.Rows.Count > 1 Then
    Application.EnableEvents = True
    Exit Sub
  End If
  
  If Not Intersect(Target, Range("D:D")) Is Nothing Then
    If iRow > 0 Then
      Rows(iRow).RowHeight = 12.75
    End If
    iRow = Target.Row
    Target.EntireRow.AutoFit
    If Target.EntireRow.Height < 22 Then
      Rows(iRow).RowHeight = 24.75
    End If
  Else
    If iRow > 0 Then
      UsedRange.SpecialCells(xlCellTypeVisible).Rows.RowHeight = 12.75
    End If
  End If
  
  Application.EnableEvents = True
End Sub

--------------
Let me know the result and I'll get back to you as soon as I can.
Cordially
Dante Amor
--------------​

 

[drag1c]

Works like a charm. Thank you sir. I understand how you were thinking about it ☺

Please lock.