Selecting Range in VBA (easy for you guys)

[Curtisyoung78]

I have this code to compare two sheets that will bold the differences between the sheets, the problem is i only want to compare from column A:Q and from row 12 down to infinity. And not the used range as specified in the code below.

Hope someone can help thanks in advance.



Sub RunCompare()


Call compareSheets("REV0", "REV1")


End Sub




Sub compareSheets(shtREV0 As String, shtREV1 As String)


Dim mycell As Range
Dim mydiffs As Integer

For Each mycell In ActiveWorkbook.Worksheets(shtREV1).UsedRange 'here I need it to look at column A:Q and from row 12 down to infinity
If Not mycell.Value = ActiveWorkbook.Worksheets(shtREV0).Cells(mycell.Row, mycell.Column).Value Then

mycell.Font.Bold = True
mydiffs = mydiffs + 1

End If
Next




ActiveWorkbook.Sheets(shtREV1).Select


End Sub

 

[Beyond_avarice]

Assuming you will always have data in Column "A"

Dim lRow as Long

lRow = Worksheets(shtREV1).Cells(Rows.Count, 1).End(xlUp).Row

ActiveWorkbook.Worksheets(shtREV1).range("A12:Q"& lRow).value

 

[shg]

Sub compareSheets(shtREV0 As String, shtREV1 As String)
  Dim wks0          As Worksheet
  Dim wks1          As Worksheet
  Dim cell          As Range

  Set wks0 = Worksheets(shtREV0)
  Set wks1 = Worksheets(shtREV1)

  For Each cell In Intersect(wks1.UsedRange, wks1.Range("A:Q"))
    If cell.Value <> wks0.Range(cell.Address).Value Then
      cell.Font.Bold = True
    End If
  Next cell
End Sub