Select the drop down option

[VICKY2007]

Sub mar()


Dim IE As New SHDocVw.InternetExplorer

IE.Visible = True
IE.navigate "http://aicf.in/national-tournament-registration/"

Do While IE.readyState <> 4
Loop

IE.document.getElementById ("national_plr_payments_form")



End Sub


Help me to select the drop down option
I don't know whether I have selected the correct element id.

 

[John_w]

Re: Help me to select the drop down option

Try this macro. You must set a reference (via Tools -> References in the VBA editor) to MS HTML Object Library.

Public Sub IE_Dropdown()

    Dim URL As String
    Dim IE As InternetExplorer
    Dim HTMLdoc As HTMLDocument
    Dim dropdown As HTMLSelectElement
    Dim dropdownText As String, dropdownIndex As Long
    
    URL = "http://aicf.in/national-tournament-registration/"
    
    Set IE = New InternetExplorer
    With IE
        .Visible = True
        .navigate URL
        While .Busy Or .readyState <> READYSTATE_COMPLETE: DoEvents: Wend
        Set HTMLdoc = .document
    End With
        
    Set dropdown = HTMLdoc.getElementsByTagName("SELECT")(0)
    dropdownText = "*National RAPID*"
    dropdownIndex = FindSelectOptionIndex(dropdown, dropdownText)
    dropdown.Focus
    dropdown.Click
    dropdown.selectedIndex = dropdownIndex
    dropdown.FireEvent "onchange"

End Sub


Private Function FindSelectOptionIndex(selectElement As HTMLSelectElement, findOptionText As String) As Long

    Dim i As Long
    
    FindSelectOptionIndex = -1
    i = 0
    While i < selectElement.Options.Length And FindSelectOptionIndex = -1
        'Debug.Print i; selectElement.Item(i).Value & " >" & selectElement.Item(i).Text & "<"
        If LCase(selectElement.Item(i).Text) Like LCase(findOptionText) Then FindSelectOptionIndex = i
        i = i + 1
    Wend

End Function