Select max date from Slicer

[mssbass]

I'm getting an Application-defined or object-defined error on SI.Selected = False. Can anyone help? Everything I've tried based on my research has failed.

[
Sub TestSlicer()

Dim sC As SlicerCache
Dim sI As SlicerItem
Dim index As Integer

Set sC = ActiveWorkbook.SlicerCaches("Slicer_ReportDt1")

sC.ClearManualFilter

For index = 1 To sC.SlicerCacheLevels.Count

    For Each sI In sC.SlicerCacheLevels(index).SlicerItems

        If sI.Name = Format$(Date - 1, "yyyy-mm-dd") Then
            sI.Selected = True
        Else
            sI.Selected = False
        End If

    Next sI

Next index

End Sub
]

 

[mssbass]

Fixed - since slicer was set to data model, it was tougher - but found the fix:

[
Sub Demo()
Dim slc As SlicerCache
Dim sli As SlicerItem
Dim iDic As Object
Set slc = ThisWorkbook.SlicerCaches("Slicer_ReportDt1")
Set iDic = CreateObject("Scripting.Dictionary")

For Each sli In slc.SlicerCacheLevels(1).SlicerItems
    If sli.Value = Format(Date - 1, "yyyy-mm-dd") Then
        iDic(sli.Name) = 1
    End If
Next

If iDic.Count = 0 Then
    MsgBox "No item selected"
Else
    slc.VisibleSlicerItemsList = iDic.Keys
End If
End Sub
]