select a cell in a filtered row

[colinharwood]

I have the following code to search for a row using the filter option, but cannot work out what to put in the *Range("???? ").Select* line of code.

Sub FindMember()
   
    Sheets("Members").Select
    Range("A5:AF95").Select
    Selection.AutoFilter
    ActiveSheet.Range("$A$5:$AF$95").AutoFilter Field:=1, Criteria1:=Sheets("PDF Membership Card").Range("X2").Value
   
    *Range("???? ").Select*
   
    ActiveCell.FormulaR1C1 = "=TODAY()"
    ActiveSheet.Range("$A$5:$AF$95").AutoFilter Field:=1
    Selection.AutoFilter
End Sub

I have tried allsorts, but because the label row and the filtered row are selected during the filter process I cannot select the col in the filtered result.
What code do I need to select col 10 in the filtered list.

 

[Skyybot]

ActiveSheet.Columns(10).Select

 

[Peter_SSs]

When posting vba code in the forum, please use the available code tags. It makes your code much easier to read/debug & copy. My signature block below has more details. I have added the tags for you this time.

It is rare in vba to need to actually select cells/ranges/worksheets etc to work with them and selecting slows your code.
Also wondering if you really want the formula =TODAY() entered into the relevant cells as tomorrow, those cell will show tomorrow's date, not todays date?

Taking a few guesses about exactly what you are trying to do, try this with a copy of your workbook.

Sub FindMember()
  With Sheets("Members")
    .AutoFilterMode = False
    With .Range("A5:AF" & .Range("A" & Rows.Count).End(xlUp).Row)
      .AutoFilter Field:=1, Criteria1:=Sheets("PDF Membership Card").Range("X2").Value
      If .Columns(1).SpecialCells(xlVisible).Count > 1 Then
        .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlVisible).Columns(10).Value = Date
      End If
      .AutoFilter
    End With
  End With
End Sub

 

[Peter_SSs]

This appears to be a duplicate of: Filter using a cell value as the criteria

In future, please do not post the same question multiple times. Per Forum Rules (#12), posts of a duplicate nature will be locked or deleted.

In relation to your question here, I have closed this thread so please continue in the linked thread.

My suggestion here may answer your question in the linked thread if the heading row matches (or is adjusted) and if the target column is actually Q and not the 10th column as stated here, change the 10 in this code to 17.