Script not executing

[Kafo]

Hello, am new to VBA and am struggling with a code that isn't running as expected.
This is what I want to achieve.
a) If one selects "Yes" in cell C8 of worksheet "summary", then rows (8:13) in worksheets "financials" & "ROI" are hidden
b) If one selects "No" in cell C8 of worksheet "summary", then rows (8:13) in worksheets "financials" & "ROI" are unhidden
c) If one selects "Yes" in cell C9 of worksheet "summary", then rows (30:50) in worksheets "financials" & "ROI" are hidden
d) If one selects "No" in cell C9 of worksheet "summary", then rows (30:50) in worksheets "financials" & "ROI" are unhidden

This is the code i wrote....not sure why its not working.....someone please help

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Target.Address <> "$C$9" Then Exit Sub
With Sheets("Financials").Rows("30:50").EntireRow
If Target.Value = "Yes" Then
.Hidden = True
Else
.Hidden = False
End If
End With

If Target.Address <> "$C$9" Then Exit Sub
With Sheets("ROI").Rows("28:45").EntireRow
If Target.Value = "No" Then
.Hidden = True
Else
.Hidden = False
End If
End With

If Target.Address <> "$C$8" Then Exit Sub
With Sheets("Financials").Rows("8:13").EntireRow
If Target.Value = "Yes" Then
.Hidden = True
Else
.Hidden = False
End If
End With

If Target.Address <> "$C$8" Then Exit Sub
With Sheets("ROI").Rows("8:13").EntireRow
If Target.Value = "No" Then
.Hidden = True
Else
.Hidden = False
End If
End With

End Sub

 

[Joe4]

Welcome to the Board!

The issue is with lines like this one near the top of your code:

If Target.Address <> "$C$9" Then Exit Sub

If you update cell C8, it will never get to that part of the code because the line shown above is telling it to exit the sub before it ever gets to that part of the code!

Try something like this instead:

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Count > 1 Then Exit Sub

Select Case Target.Address
    
    Case "$C$9"
        With Sheets("Financials").Rows("30:50").EntireRow
            If Target.Value = "Yes" Then
                .Hidden = True
            Else
                .Hidden = False
            End If
        End With
    
        With Sheets("ROI").Rows("28:45").EntireRow
            If Target.Value = "No" Then
                .Hidden = True
            Else
                .Hidden = False
            End If
    End With

    Case "$C$8"
        With Sheets("Financials").Rows("8:13").EntireRow
            If Target.Value = "Yes" Then
                .Hidden = True
            Else
                .Hidden = False
            End If
        End With

        With Sheets("ROI").Rows("8:13").EntireRow
            If Target.Value = "No" Then
                .Hidden = True
            Else
                .Hidden = False
            End If
        End With

    End Select
    
End Sub

 

[Kafo]

@Joe4 Thank you very very much!

 

[Joe4]

You are welcome.
Glad I was able to help!