scaling up print range to fit page width...

[RobbieC]

Hi there, I have a workbook and each sheet has a different range set as the print area. Some are bigger than others but on the whole they are all pretty similar.

I'd like to be able to set each page's print setup so that each 'print area' range fits to the width of the print paper (or PDF width)

This works for me:

With ActiveSheet.PageSetup
    .PaperSize = xlPaperA4
    .Orientation = xlPortrait
    .LeftMargin = Application.CentimetersToPoints(0)
    .RightMargin = Application.CentimetersToPoints(0)
    .TopMargin = Application.CentimetersToPoints(0)
    .BottomMargin = Application.CentimetersToPoints(0)
    .HeaderMargin = Application.CentimetersToPoints(0)
    .FooterMargin = Application.CentimetersToPoints(0)
    .CenterHorizontally = True
    .CenterVertically = False
    .Zoom = False
    .FitToPagesWide = 1
    .FitToPagesTall = False
End With

but only if the print area is BIGGER than the width of A4. It doesn't seem to 'scale up' if the range is smaller...

Can you help me out to scale the print area up to the width of the A4 print area?

Thanks very much

 

[Worf]

Hi

Sub zooom()
Dim ws As Worksheet, i%, pc%
Const inc As Integer = 5                            ' zoom increase
Const safe As Integer = 20                          ' max iterations
Set ws = ActiveSheet
i = 1
pc = ws.PageSetup.Pages.Count
Do
    ws.PageSetup.Zoom = ws.PageSetup.Zoom + inc
    i = i + 1
    ActiveWindow.View = xlNormalView
    ActiveWindow.View = xlPageBreakPreview          ' update page count
Loop While i < safe And ws.PageSetup.Pages.Count = pc
If ws.PageSetup.Pages.Count > pc Then _
ws.PageSetup.Zoom = ws.PageSetup.Zoom - inc         ' spilled onto next page
MsgBox ws.PageSetup.Zoom, , "Final zoom"
End Sub