saving .doc as .txt w/VBA from browser

[tx12345]

Hi

Using VBA, i can go to a htm page, grab the text, and so on. but when going to a certain URL it opens a word doc in the browser. the link changes from .htm to .doc

what i'd like to do is save this doc as a .txt file or just grab the text.

TIA

tx

 

[Oorang]

Option Explicit
Sub EarlyBoundExample()
'Requires reference to the Microsoft Internet Controls
'Requires reference to Microsoft Word xx.x object Library
Const strURL As String = "http://www.lancs.ac.uk/staff/msacfj/MSC%20VBA%20Course%20Outline.doc"
Dim IE As SHDocVw.InternetExplorer
Dim doc As Word.Document
Set IE = New InternetExplorer
IE.Navigate strURL
Do Until IE.ReadyState = READYSTATE_COMPLETE
DoEvents
Loop
Set doc = IE.Document
MsgBox doc.Range.Text
IE.Quit
End Sub
Sub LateBoundExample()
Const strURL As String = "http://www.lancs.ac.uk/staff/msacfj/MSC%20VBA%20Course%20Outline.doc"
Dim IE As Object
Dim doc As Object
Set IE = VBA.CreateObject("InternetExplorer.Application")
IE.Navigate strURL
Do Until IE.ReadyState = 4
DoEvents
Loop
Set doc = IE.Document
MsgBox doc.Range.Text
IE.Quit
End Sub

 

[tx12345]

sweet. thanks! works like a charm

tx