Saving a copy of the current workbbook as template

[Guraknugen]

I guess I need some help, I have tried "everything" (obviously not, but I reached EndOfIdeas).
I want to save the current workbook as a macro enabled template at some destination, but I don't want the template to then be my "current workbook".

ThisWorkbook.SaveCopyAs /Full/Path/To/Template.xltm, FileFormat:=xlOpenXMLTemplateMacroEnabled

The problem is that ThisWorkbook.SaveCopyAs doesn't support FileFormat.

Any suggestions for workarounds?

 

[footoo]

.

 

[dmt32]

SaveCopyAs does not have any of the attributes of SaveAs that allows you to specify file type – It just makes a copy of your current workbook with your chosen file name.

A solution I provided to another here with similar requirement was to create code that would:
- Save active workbook
- Use SaveAs to save a copy with the specified filename & file type
- Re-Open the saved workbook
- Close the copy workbook.

Try this update to code I suggested & see if it helps you.

Place in a STANDARD module

 Sub SaveCopyAs(ByVal FileName As String, ByVal FileFormat As XlFileFormat, Optional ByVal wb As Workbook)    
   'dmt32 jan 2018
    Dim ActiveFile As String
    
    On Error GoTo myerror
    If wb Is Nothing Then Set wb = ThisWorkbook
    If wb.Path = "" Then Err.Raise 76
    
    With Application
        .ScreenUpdating = False: .EnableEvents = False: .DisplayAlerts = False
    End With
    
    With wb
        .Save
        ActiveFile = .FullName
        .SaveAs FileName:=FileName, FileFormat:=FileFormat
    End With


    
    Workbooks.Open ActiveFile
    
    wb.Close False
    
myerror:
    With Application
        .ScreenUpdating = True: .EnableEvents = True: .DisplayAlerts = True
    End With
    If Err > 0 Then MsgBox (Error(Err)), 48, "Error"
End Sub

And call it in similar way to your published requirement

 SaveCopyAs "C:\Full\Path\To\TemplateName", FileFormat:=xlOpenXMLTemplateMacroEnabled

Hope Helpful

Dave