Save Multiple Sheets In Workbook As PDF Based on Cell Condition And Name As Cell Value

[YourHouseKey]

Hello,

Looking for assistance with saving multiple sheets in a workbook as individual PDFs in a defined directory where the file name is based on a cell value. However, I only want to save sheets when a cell within that sheet meets a certain criteria.

EXAMPLE: If cell B116 = Y, Then save sheet as PDF with a file name based cell B120. If cell B116 <> Y, Then move on to the next sheet.

I'd like this to sweep through all sheets in my workbook and only export sheets where cell B116 = Y.

Can anybody help with some VBA code to provide a solution?

Thank you!

 

[John_w]

Welcome to MrExcel forums.

Try this macro, changing the saveInFolder as required.

Public Sub Create_PDFs()

    Dim saveInFolder As String
    Dim ws As Worksheet
    
    saveInFolder = "C:\path\to\folder\"     'CHANGE THIS
    If Right(saveInFolder, 1) <> "\" Then saveInFolder = saveInFolder & "\"
    
    With ActiveWorkbook
        For Each ws In .Worksheets
            If ws.Range("B116").Value = "Y" Then
                ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=saveInFolder & ws.Range("B120").Text & ".pdf", _
                    Quality:=xlQualityMinimum, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            End If
        Next
    End With
    
End Sub

 

[YourHouseKey]

Welcome to MrExcel forums.

Try this macro, changing the saveInFolder as required.

Public Sub Create_PDFs()

    Dim saveInFolder As String
    Dim ws As Worksheet
   
    saveInFolder = "C:\path\to\folder\"     'CHANGE THIS
    If Right(saveInFolder, 1) <> "\" Then saveInFolder = saveInFolder & "\"
   
    With ActiveWorkbook
        For Each ws In .Worksheets
            If ws.Range("B116").Value = "Y" Then
                ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=saveInFolder & ws.Range("B120").Text & ".pdf", _
                    Quality:=xlQualityMinimum, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            End If
        Next
    End With
   
End Sub

Hi John_w,

Thank you for providing. This worked perfectly in my workbook. Ran into a couple of runtime errors, but a few changes to my workbook resolved the issues.

I appreciate the assistance.

Thanks again!