save file, delete the assigned button on new saved worksheet

[Seeker2013]

I have a quotation form that have two buttons.

One is click and will generate a new quote number.
Another is click and it will be save with the assigned path and file name format.

When I click on save File, the new saved files will also copy the buttons and macron, which I like to delete the buttons and macro completely.

here is my code:

Sub SaveWSToNewWBs()
Dim wb As Workbook
Dim ws As Worksheet
For Each ws In ThisWorkbook.Worksheets
    'ws.Copy
    Set wb = ActiveWorkbook
     wb.SaveAs ThisWorkbook.Path & "\" & ws.Name & ws.Range("G3").Value & ".xls"
    wb.Close False
Next ws
End Sub

what should I add to be able to delete the buttons and macro in the new destination file?

Many thanks in advance.

 

[Domenic]

The following macro assumes that the buttons are form controls, not ActiveX controls. Also, the macro settings need to allow access to the VBA project model...

Developer > Code > Macro Security > Macro Settings > Developer Macro Settings

...and select 'Trust access to the VBA project model'. So for each worksheet within the workbook, a new workbook is created with a copy of the sheet, all the buttons on the sheet are deleted, any code within the sheet module is deleted, etc.

Option Explicit

Sub SaveWSToNewWBs()

    Dim VBP     As Object
    Dim wb      As Workbook
    Dim ws      As Worksheet
    Dim Msg     As String
    
    On Error Resume Next
    Set VBP = ThisWorkbook.VBProject
    On Error GoTo 0
    If VBP Is Nothing Then
        Msg = "Your macro settings do not allow this macro to run.  "
        Msg = Msg & "You'll need to allow access to the VBA project model."
        MsgBox Msg, vbExclamation, "Macro Settings"
        Exit Sub
    End If
    
    For Each ws In ThisWorkbook.Worksheets
        ws.Copy
        Set wb = ActiveWorkbook
        With wb
            .Worksheets(1).Buttons.Delete
            With .VBProject.VBComponents(.Worksheets(1).CodeName).CodeModule
                .DeleteLines 1, .CountOfLines
            End With
            .SaveAs ThisWorkbook.Path & "\" & ws.Name & ws.Range("G3").Value & ".xls"
            .Close False
        End With
    Next ws
    
End Sub

Hope this helps!